Make tests work.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key )

2 files changed, 58 insertions, 1 deletions

diff --git a/dev-ruby/facter/ChangeLog b/dev-ruby/facter/ChangeLog
index 806a1131af16..8e1b3c84065d 100644
--- a/dev-ruby/facter/ChangeLog
+++ b/dev-ruby/facter/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/facter
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/facter/ChangeLog,v 1.89 2014/02/14 07:10:58 prometheanfire Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/facter/ChangeLog,v 1.90 2014/03/02 21:58:44 mrueg Exp $
+
+*facter-1.7.5-r1 (02 Mar 2014)
+
+  02 Mar 2014; Manuel Rüger <mrueg@gentoo.org> +facter-1.7.5-r1.ebuild:
+  Make tests work.
 
 *facter-1.7.5 (14 Feb 2014)
 
diff --git a/dev-ruby/facter/facter-1.7.5-r1.ebuild b/dev-ruby/facter/facter-1.7.5-r1.ebuild
new file mode 100644
index 000000000000..ec81c83e54bc
--- /dev/null
+++ b/dev-ruby/facter/facter-1.7.5-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/facter/facter-1.7.5-r1.ebuild,v 1.1 2014/03/02 21:58:44 mrueg Exp $
+
+EAPI=5
+
+USE_RUBY="ruby19 jruby"
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_RECIPE_TEST="rspec"
+RUBY_FAKEGEM_EXTRADOC="README.md"
+RUBY_FAKEGEM_BINWRAP="facter"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A cross-platform Ruby library for retrieving facts from operating systems"
+HOMEPAGE="http://www.puppetlabs.com/puppet/related-projects/facter/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="+dmi +pciutils"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+
+CDEPEND="
+	sys-apps/net-tools
+	sys-apps/lsb-release
+	dmi? ( sys-apps/dmidecode )
+	pciutils? ( sys-apps/pciutils )"
+
+RDEPEND+=" ${CDEPEND}"
+DEPEND+=" test? ( ${CDEPEND} )"
+
+#RUBY_PATCHES=( ${P}-fix-proc-self-status.patch )
+
+ruby_add_bdepend "test? ( >=dev-ruby/mocha-0.10.5:0.10 )"
+
+all_ruby_prepare() {
+	# Provide explicit path since /sbin is not in the default PATH on
+	# Gentoo.
+	sed -i -e 's:arp -an:/sbin/arp -an:' lib/facter/util/ec2.rb spec/unit/util/ec2_spec.rb || die
+
+	# Ensure the correct version of mocha is used without using bundler.
+	sed -i -e '1igem "mocha", "~>0.10.5"' spec/spec_helper.rb || die
+
+	sed -i -e '1irequire "rspec-expectations"' spec/puppetlabs_spec/matchers.rb || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	# Create the directory for custom facts.
+	keepdir /etc/facter/facts.d
+}