Version bump. Switch to python-single-r1.

(Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 88 insertions, 1 deletions

diff --git a/dev-util/meld/ChangeLog b/dev-util/meld/ChangeLog
index 96d93cfb5eb7..1aa42c060c6d 100644
--- a/dev-util/meld/ChangeLog
+++ b/dev-util/meld/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/meld
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/ChangeLog,v 1.161 2013/03/29 13:32:00 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/ChangeLog,v 1.162 2013/03/30 21:27:48 eva Exp $
+
+*meld-1.7.1 (30 Mar 2013)
+
+  30 Mar 2013; Gilles Dartiguelongue <eva@gentoo.org> +meld-1.7.1.ebuild:
+  Version bump. Switch to python-single-r1.
 
   29 Mar 2013; Agostino Sarubbo <ago@gentoo.org> meld-1.7.0.ebuild:
   Stable for ia64, wrt bug #458984
diff --git a/dev-util/meld/meld-1.7.1.ebuild b/dev-util/meld/meld-1.7.1.ebuild
new file mode 100644
index 000000000000..17f1eaad656c
--- /dev/null
+++ b/dev-util/meld/meld-1.7.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/meld/meld-1.7.1.ebuild,v 1.1 2013/03/30 21:27:48 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python2_{6,7} )
+
+inherit eutils python-single-r1 gnome2 multilib
+
+DESCRIPTION="A graphical diff and merge tool"
+HOMEPAGE="http://meldmerge.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+highlight gnome"
+
+# FIXME: switch pygtksourceview and gconf-python to python-r1
+RDEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/pygtk-2.14:2[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-2.8:2[${PYTHON_USEDEP}]
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	highlight? ( >=dev-python/pygtksourceview-2.10[${PYTHON_USEDEP}] )
+	gnome? ( >=dev-python/gconf-python-2.22:2 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	dev-util/intltool
+	app-text/scrollkeeper
+"
+
+src_prepare() {
+	# fix the prefix so its not in */local/*
+	sed -e "s:/usr/local:${EPREFIX}/usr:" \
+		-e "s:\$(prefix)/lib:\$(prefix)/$(get_libdir):" \
+		-i INSTALL || die "sed 1 failed"
+
+	# don't install anything to /usr/share/doc/meld
+	sed -e "s:\$(docdir)/meld:\$(docdir)/${PF}:" \
+		-i INSTALL || die "sed 2 failed"
+
+	# don't run scrollkeeper (with the wrong path),
+	# leave that to gnome2.eclass #145833
+	sed -e '/scrollkeeper-update/s/\t/&#/' \
+		-i help/*/Makefile || die "sed 4 failed"
+
+	# don't run update-*-database, leave that to eclass
+	sed -e '/update-.*-database/d' \
+		-i Makefile || die "sed 5 failed"
+
+	strip-linguas -i "${S}/po"
+	local mylinguas=""
+	for x in ${LINGUAS}; do
+		mylinguas="${mylinguas} ${x}.po"
+	done
+
+	if [ -n "${mylinguas}" ]; then
+		sed -e "s/PO:=.*/PO:=${mylinguas}/" \
+			-i po/Makefile || die "sed 6 failed"
+	fi
+
+	# Fix .desktop entry, upstream bug #686978
+	sed -e '/Encoding/d' \
+		-e 's/(MimeType.*)/\1/' \
+		-i data/meld.desktop.in || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	:
+}
+
+src_install() {
+	DOCS="NEWS"
+	gnome2_src_install
+	python_fix_shebang "${ED}"/usr/bin
+	doman meld.1
+}