Adding ultrastar-songs support. Bug #198283

(Portage version: 2.1.3.19)

3 files changed, 104 insertions, 1 deletions

diff --git a/games-arcade/ultrastar-ng/ChangeLog b/games-arcade/ultrastar-ng/ChangeLog
index 1912313e9c43..11dacaecb0a9 100644
--- a/games-arcade/ultrastar-ng/ChangeLog
+++ b/games-arcade/ultrastar-ng/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for games-arcade/ultrastar-ng
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-arcade/ultrastar-ng/ChangeLog,v 1.3 2007/11/05 18:16:41 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/ultrastar-ng/ChangeLog,v 1.4 2007/12/03 22:03:13 tupone Exp $
+
+*ultrastar-ng-0.2.1-r1 (03 Dec 2007)
+
+  03 Dec 2007; Tupone Alfredo <tupone@gentoo.org>
+  +ultrastar-ng-0.2.1-r1.ebuild:
+  Adding ultrastar-songs support. Bug #198283 by Lasse Kärkkäinen
 
 *ultrastar-ng-0.2.1 (05 Nov 2007)
 
diff --git a/games-arcade/ultrastar-ng/files/digest-ultrastar-ng-0.2.1-r1 b/games-arcade/ultrastar-ng/files/digest-ultrastar-ng-0.2.1-r1
new file mode 100644
index 000000000000..c698c658579c
--- /dev/null
+++ b/games-arcade/ultrastar-ng/files/digest-ultrastar-ng-0.2.1-r1
@@ -0,0 +1,6 @@
+MD5 8df1c7ca15f23e215f4741e3a468dd1e UltraStar-ng-0.2.1.tar.gz 1687366
+RMD160 6ab305e67eabda09951a0e459798c7a66e11d801 UltraStar-ng-0.2.1.tar.gz 1687366
+SHA256 a93daad488c07217512fbf6a2f5ded39cf71664736dd3a33a725241838554d6d UltraStar-ng-0.2.1.tar.gz 1687366
+MD5 c50f0bc7c53530defd6ee2146c2d1894 ultrastar-songs-1.tar.bz2 6595544
+RMD160 ba7521cdb0edc4cdc34deb45380ca98c4d7d8267 ultrastar-songs-1.tar.bz2 6595544
+SHA256 6efe78f8fa66e7fc7a980136cefe9569e080cb154e981f578505944fc88b016c ultrastar-songs-1.tar.bz2 6595544
diff --git a/games-arcade/ultrastar-ng/ultrastar-ng-0.2.1-r1.ebuild b/games-arcade/ultrastar-ng/ultrastar-ng-0.2.1-r1.ebuild
new file mode 100644
index 000000000000..f76eb629161d
--- /dev/null
+++ b/games-arcade/ultrastar-ng/ultrastar-ng-0.2.1-r1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/ultrastar-ng/ultrastar-ng-0.2.1-r1.ebuild,v 1.1 2007/12/03 22:03:13 tupone Exp $
+
+inherit eutils games
+
+MY_PN=UltraStar-ng
+MY_P=${MY_PN}-${PV}
+SONGS_PN=ultrastar-songs
+SONGS_P=${SONGS_PN}-1
+
+DESCRIPTION="SingStar GPL clone"
+HOMEPAGE="http://sourceforge.net/projects/ultrastar-ng/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz
+	songs? ( mirror://sourceforge/${PN}/${SONGS_P}.tar.bz2 )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="novideo opengl xine debug alsa gstreamer portaudio songs"
+
+RDEPEND="gnome-base/librsvg
+	dev-libs/boost
+	x11-libs/pango
+	media-libs/sdl-image
+	media-libs/sdl-gfx
+	xine? ( media-libs/xine-lib )
+	!xine? ( media-libs/gstreamer )
+	opengl? (
+		virtual/opengl
+		virtual/glu
+	)
+	alsa? ( media-libs/alsa-lib )
+	portaudio? ( media-libs/portaudio )
+	gstreamer? ( >=media-libs/gstreamer-0.10 )
+	!novideo? ( media-libs/smpeg )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	games_pkg_setup
+	if use opengl && ! built_with_use media-libs/libsdl opengl ; then
+		eerror "opengl flag set, but libsdl wasn't build with opengl support"
+	fi
+	if ! built_with_use --missing true dev-libs/boost threads ; then
+		eerror "Please emerge dev-libs/boost with USE=threads"
+	fi
+}
+
+src_compile() {
+	local myconf
+
+	if use novideo; then
+		myconf="--with-video=disable"
+	else
+		myconf="--with-video=smpeg"
+	fi
+	if use opengl; then
+		myconf="$myconf --with-graphic-driver=opengl"
+	else
+		myconf="$myconf --with-graphic-driver=sdl"
+	fi
+	if use xine; then
+		myconf="$myconf --with-audio=xine"
+	else
+		myconf="$myconf --with-audio=gstreamer"
+	fi
+
+	egamesconf \
+		${myconf} \
+		$(use_enable debug) \
+		$(use_enable portaudio record-portaudio) \
+		$(use_enable gstreamer record-gst) \
+		$(use_enable alsa record-alsa) \
+		|| die
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	keepdir "${GAMES_DATADIR}"/${PN}/songs
+	if use songs; then
+		insinto "${GAMES_DATADIR}"/${PN}
+		doins -r ../songs
+	fi
+	mv "${D}${GAMES_DATADIR}"/{applications,pixmaps} "${D}"/usr/share/
+	dodoc AUTHORS ChangeLog README TODO
+	prepgamesdirs
+}