Add run-time dependency on sys-apps/lsb-release (required by lxsession-logout).

(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 0x39E7AB2E)

2 files changed, 62 insertions, 1 deletions

diff --git a/lxde-base/lxsession/ChangeLog b/lxde-base/lxsession/ChangeLog
index 0b8a8123e508..ed84876301e8 100644
--- a/lxde-base/lxsession/ChangeLog
+++ b/lxde-base/lxsession/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for lxde-base/lxsession
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxsession/ChangeLog,v 1.49 2013/10/23 09:45:42 nullishzero Exp $
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxsession/ChangeLog,v 1.50 2013/10/23 09:53:44 nullishzero Exp $
+
+*lxsession-0.4.9.2-r1 (23 Oct 2013)
+
+  23 Oct 2013; Pavel Kazakov <nullishzero@gentoo.org>
+  +lxsession-0.4.9.2-r1.ebuild:
+  Add run-time dependency on sys-apps/lsb-release (required by lxsession-
+  logout).
 
   23 Oct 2013; Pavel Kazakov <nullishzero@gentoo.org> lxsession-0.4.9.2.ebuild:
   Add dependency on sys-auth/polkit; bug #488054
diff --git a/lxde-base/lxsession/lxsession-0.4.9.2-r1.ebuild b/lxde-base/lxsession/lxsession-0.4.9.2-r1.ebuild
new file mode 100644
index 000000000000..785410a77b28
--- /dev/null
+++ b/lxde-base/lxsession/lxsession-0.4.9.2-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/lxde-base/lxsession/lxsession-0.4.9.2-r1.ebuild,v 1.1 2013/10/23 09:53:44 nullishzero Exp $
+
+EAPI=5
+
+VALA_MIN_API_VERSION="0.14"
+VALA_MAX_API_VERSION="0.20"
+
+inherit vala autotools eutils
+
+DESCRIPTION="LXDE session manager (lite version)"
+HOMEPAGE="http://lxde.sf.net/"
+SRC_URI="mirror://sourceforge/lxde/${P}.tar.gz"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~x86 ~arm-linux ~x86-linux"
+SLOT="0"
+# upower USE flag is enabled by default in the desktop profile
+IUSE="nls upower"
+
+COMMON_DEPEND="dev-libs/glib:2
+	dev-libs/libgee:0
+	dev-libs/dbus-glib
+	lxde-base/lxde-common
+	sys-auth/polkit
+	x11-libs/gtk+:2
+	x11-libs/libX11
+	sys-apps/dbus"
+RDEPEND="${COMMON_DEPEND}
+	!lxde-base/lxsession-edit
+	sys-apps/lsb-release
+	upower? ( sys-power/upower )"
+DEPEND="${COMMON_DEPEND}
+	$(vala_depend)
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	x11-proto/xproto"
+
+DOCS="AUTHORS ChangeLog README"
+
+src_prepare() {
+	# bug #488082
+	epatch "${FILESDIR}"/${P}-makefile.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	# dbus is used for restart/shutdown (CK, logind?), and suspend/hibernate (UPower)
+	econf \
+		$(use_enable nls)
+}