Version bump.

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key A792A613)

2 files changed, 98 insertions, 2 deletions

diff --git a/net-nntp/tin/ChangeLog b/net-nntp/tin/ChangeLog
index dbff89f6dab1..47bc8f887202 100644
--- a/net-nntp/tin/ChangeLog
+++ b/net-nntp/tin/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-nntp/tin
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nntp/tin/ChangeLog,v 1.39 2012/10/30 23:02:13 jer Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-nntp/tin/ChangeLog,v 1.40 2013/01/08 18:01:52 jer Exp $
+
+*tin-2.1.2 (08 Jan 2013)
+
+  08 Jan 2013; Jeroen Roovers <jer@gentoo.org> +tin-2.1.2.ebuild:
+  Version bump.
 
 *tin-2.1.0 (30 Oct 2012)
 
diff --git a/net-nntp/tin/tin-2.1.2.ebuild b/net-nntp/tin/tin-2.1.2.ebuild
new file mode 100644
index 000000000000..eb9beb8f5a00
--- /dev/null
+++ b/net-nntp/tin/tin-2.1.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-nntp/tin/tin-2.1.2.ebuild,v 1.1 2013/01/08 18:01:52 jer Exp $
+
+EAPI=4
+inherit eutils toolchain-funcs versionator
+
+DESCRIPTION="A threaded NNTP and spool based UseNet newsreader"
+HOMEPAGE="http://www.tin.org/"
+SRC_URI="ftp://ftp.tin.org/pub/news/clients/tin/v$(get_version_component_range 1-2)/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="cancel-locks debug doc +etiquette evil forgery gpg idn ipv6 mime nls sasl socks5 spell unicode"
+
+RDEPEND="
+	dev-libs/libpcre
+	dev-libs/uulib
+	gpg? ( app-crypt/gnupg )
+	idn? ( net-dns/libidn )
+	mime? ( net-mail/metamail )
+	net-misc/urlview
+	nls? ( sys-devel/gettext )
+	sasl? ( virtual/gsasl )
+	socks5? ( net-proxy/dante )
+	sys-libs/ncurses[unicode?]
+	unicode? ( dev-libs/icu )
+"
+
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Do not strip
+	sed -i src/Makefile.in -e 's| -s | |g' || die
+}
+
+src_configure() {
+	if use evil || use cancel-locks; then
+		sed -i -e"s/# -DEVIL_INSIDE/-DEVIL_INSIDE/" src/Makefile.in
+	fi
+
+	if use forgery
+	then
+		sed -i -e"s/^CPPFLAGS.*/& -DFORGERY/" src/Makefile.in
+	fi
+
+	local screen="ncurses"
+	use unicode && screen="ncursesw"
+
+	tc-export CC
+
+	econf \
+		$(use_enable cancel-locks) \
+		$(use_enable debug) \
+		$(use_enable etiquette) \
+		$(use_enable gpg pgp-gpg) \
+		$(use_enable ipv6) \
+		$(use_enable nls) \
+		$(use_with mime metamail /usr) \
+		$(use_with socks5 socks) $(use_with socks5) \
+		$(use_with spell ispell /usr) \
+		--disable-mime-strict-charset \
+		--enable-echo \
+		--enable-nntp-only \
+		--enable-prototypes \
+		--with-coffee  \
+		--with-nntp-default-server="${TIN_DEFAULT_SERVER:-${NNTPSERVER:-news.gmane.org}}" \
+		--with-pcre=/usr \
+		--with-screen=${screen}
+}
+
+src_compile() {
+	emake build
+}
+
+src_install() {
+	default
+
+	# File collision?
+	rm -f "${ED}"/usr/share/man/man5/{mbox,mmdf}.5
+
+	dodoc doc/{CHANGES{,.old},CREDITS,TODO,WHATSNEW}
+	use doc && dodoc doc/{*.sample,*.txt}
+
+	insinto /etc/tin
+	doins doc/tin.defaults
+}