Bump for #497592

(Portage version: 2.2.8/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 87 insertions, 2 deletions

diff --git a/www-client/weboob/ChangeLog b/www-client/weboob/ChangeLog
index 15b43d6308fc..4e83e25eba6a 100644
--- a/www-client/weboob/ChangeLog
+++ b/www-client/weboob/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for www-client/weboob
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/weboob/ChangeLog,v 1.6 2013/09/12 20:59:05 mgorny Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/weboob/ChangeLog,v 1.7 2014/01/09 04:52:46 patrick Exp $
+
+*weboob-0h (09 Jan 2014)
+
+  09 Jan 2014; Patrick Lauer <patrick@gentoo.org> +weboob-0h.ebuild:
+  Bump for #497592
 
   12 Sep 2013; Michał Górny <mgorny@gentoo.org> weboob-0g.ebuild,
   weboob-9998.ebuild, weboob-9999.ebuild:
diff --git a/www-client/weboob/weboob-0h.ebuild b/www-client/weboob/weboob-0h.ebuild
new file mode 100644
index 000000000000..56c0fc16c4c1
--- /dev/null
+++ b/www-client/weboob/weboob-0h.ebuild
@@ -0,0 +1,80 @@
+# Copyright 2010-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/weboob/weboob-0h.ebuild,v 1.1 2014/01/09 04:52:46 patrick Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1 gnome2-utils versionator
+
+if [ "$PV" == "9999" ]; then
+	EGIT_REPO_URI="git://git.symlink.me/pub/${PN}/devel.git"
+	inherit git-2
+	KEYWORDS=""
+	SRC_URI=""
+elif [ "$PV" == "9998" ]; then
+	EGIT_REPO_URI="git://git.symlink.me/pub/${PN}/stable.git"
+	inherit git-2
+	KEYWORDS=""
+	SRC_URI=""
+else
+	KEYWORDS="~x86 ~amd64"
+	MY_P="${PN}-$(version_format_string '$1.$2')"
+	SRC_URI="http://symlink.me/attachments/download/235/${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+DESCRIPTION="Weboob (Web Outside of Browsers) provides several applications to interact with a lot of websites."
+HOMEPAGE="http://weboob.org/"
+
+LICENSE="AGPL-3"
+SLOT="0"
+IUSE="X +secure-updates fast-libs"
+
+DEPEND="X? ( >=dev-python/PyQt4-4.9.4-r1[X,phonon,${PYTHON_USEDEP}] )
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+RDEPEND="${DEPEND}
+	dev-python/prettytable[${PYTHON_USEDEP}]
+	dev-python/html2text[${PYTHON_USEDEP}]
+	dev-python/mechanize[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	virtual/python-imaging[${PYTHON_USEDEP}]
+	dev-python/gdata[${PYTHON_USEDEP}]
+	dev-python/feedparser[${PYTHON_USEDEP}]
+	dev-python/termcolor[${PYTHON_USEDEP}]
+	secure-updates? ( app-crypt/gnupg )
+	fast-libs? (
+		dev-python/simplejson[${PYTHON_USEDEP}]
+		dev-python/pyyaml[libyaml,${PYTHON_USEDEP}]
+	)
+	>=dev-python/lxml-3.0[${PYTHON_USEDEP}]
+	dev-python/cssselect[${PYTHON_USEDEP}]"
+
+DOCS=( AUTHORS COPYING ChangeLog README INSTALL )
+
+python_configure_all() {
+	mydistutilsargs=(
+		$(usex X '--qt' '--no-qt')
+		$(usex X '--xdg' '--no-xdg')
+	)
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	insinto /usr/share/${PN}/
+	doins -r contrib/*
+}
+
+pkg_preinst() {
+	use X && gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	use X && gnome2_icon_cache_update
+	elog 'You should now run "weboob-config update" (as your login user).'
+}
+
+pkg_postrm() {
+	use X && gnome2_icon_cache_update
+}