Add multilib support, update license, drop old.

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0x18E5B6F2D8D5EC8D)

6 files changed, 83 insertions, 69 deletions

diff --git a/x11-libs/libnotify/ChangeLog b/x11-libs/libnotify/ChangeLog
index 27dcfaf5ec2d..a9eff526344a 100644
--- a/x11-libs/libnotify/ChangeLog
+++ b/x11-libs/libnotify/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for x11-libs/libnotify
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/ChangeLog,v 1.104 2013/09/08 15:24:31 eva Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/ChangeLog,v 1.105 2014/11/24 02:50:14 tetromino Exp $
+
+*libnotify-0.7.6-r1 (24 Nov 2014)
+
+  24 Nov 2014; Alexandre Rostovtsev <tetromino@gentoo.org>
+  -libnotify-0.7.5.ebuild, libnotify-0.7.5-r1.ebuild, libnotify-0.7.6.ebuild,
+  +libnotify-0.7.6-r1.ebuild, metadata.xml:
+  Add multilib support, update license, drop old.
 
 *libnotify-0.7.6 (08 Sep 2013)
 
diff --git a/x11-libs/libnotify/libnotify-0.7.5-r1.ebuild b/x11-libs/libnotify/libnotify-0.7.5-r1.ebuild
index 18920cbaf204..f3fee9ed4922 100644
--- a/x11-libs/libnotify/libnotify-0.7.5-r1.ebuild
+++ b/x11-libs/libnotify/libnotify-0.7.5-r1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/libnotify-0.7.5-r1.ebuild,v 1.11 2013/05/01 11:14:34 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/libnotify-0.7.5-r1.ebuild,v 1.12 2014/11/24 02:50:14 tetromino Exp $
 
 EAPI=5
 inherit autotools gnome.org
@@ -8,7 +8,7 @@ inherit autotools gnome.org
 DESCRIPTION="A library for sending desktop notifications"
 HOMEPAGE="http://git.gnome.org/browse/libnotify"
 
-LICENSE="LGPL-2.1"
+LICENSE="LGPL-2.1+"
 SLOT="0"
 KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
 IUSE="doc +introspection test"
diff --git a/x11-libs/libnotify/libnotify-0.7.5.ebuild b/x11-libs/libnotify/libnotify-0.7.5.ebuild
deleted file mode 100644
index 484314cd1990..000000000000
--- a/x11-libs/libnotify/libnotify-0.7.5.ebuild
+++ /dev/null
@@ -1,57 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/libnotify-0.7.5.ebuild,v 1.12 2013/03/19 15:47:15 ssuominen Exp $
-
-EAPI=5
-inherit autotools gnome.org
-
-DESCRIPTION="A library for sending desktop notifications"
-HOMEPAGE="http://git.gnome.org/browse/libnotify"
-SRC_URI="${SRC_URI}
-	mirror://gentoo/introspection-20110205.m4.tar.bz2"
-
-LICENSE="LGPL-2.1"
-SLOT="0"
-KEYWORDS="alpha amd64 arm ia64 ~mips ppc ppc64 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
-IUSE="doc +introspection +symlink test"
-
-RDEPEND=">=dev-libs/glib-2.26
-	x11-libs/gdk-pixbuf:2
-	introspection? ( >=dev-libs/gobject-introspection-0.9.12 )"
-DEPEND="${RDEPEND}
-	dev-util/gtk-doc-am
-	virtual/pkgconfig
-	doc? ( >=dev-util/gtk-doc-1.14 )
-	symlink? ( !x11-misc/tinynotify-send[symlink] )
-	test? ( x11-libs/gtk+:3 )"
-PDEPEND="virtual/notification-daemon"
-
-DOCS=( AUTHORS ChangeLog NEWS )
-
-src_prepare() {
-	sed -i -e 's:noinst_PROG:check_PROG:' tests/Makefile.am || die
-
-	if ! use test; then
-		sed -i -e '/PKG_CHECK_MODULES(TESTS/d' configure.ac || die
-	fi
-
-	if has_version dev-libs/gobject-introspection; then
-		eautoreconf
-	else
-		AT_M4DIR=${WORKDIR} eautoreconf
-	fi
-}
-
-src_configure() {
-	econf \
-		--disable-static \
-		$(use_enable introspection)
-}
-
-src_install() {
-	default
-	prune_libtool_files
-
-	mv -vf "${ED}"usr/bin/{,${PN}-}notify-send #379941
-	use symlink && dosym ${PN}-notify-send /usr/bin/notify-send
-}
diff --git a/x11-libs/libnotify/libnotify-0.7.6-r1.ebuild b/x11-libs/libnotify/libnotify-0.7.6-r1.ebuild
new file mode 100644
index 000000000000..fb265adee681
--- /dev/null
+++ b/x11-libs/libnotify/libnotify-0.7.6-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/libnotify-0.7.6-r1.ebuild,v 1.1 2014/11/24 02:50:14 tetromino Exp $
+
+EAPI=5
+inherit autotools eutils gnome.org multilib-minimal
+
+DESCRIPTION="A library for sending desktop notifications"
+HOMEPAGE="http://git.gnome.org/browse/libnotify"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="+introspection test"
+
+COMMON_DEPEND="app-admin/eselect-notify-send
+	>=dev-libs/glib-2.26:2[${MULTILIB_USEDEP}]
+	x11-libs/gdk-pixbuf:2[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.32 )"
+RDEPEND="${COMMON_DEPEND}
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-gtklibs-20140508-r4
+		!app-emulation/emul-linux-x86-gtklibs[-abi_x86_32(-)]
+	)"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/gobject-introspection-common-1.32
+	>=dev-util/gtk-doc-am-1.14
+	virtual/pkgconfig
+	test? ( x11-libs/gtk+:3[${MULTILIB_USEDEP}] )"
+PDEPEND="virtual/notification-daemon"
+
+DOCS=( AUTHORS ChangeLog NEWS )
+
+src_prepare() {
+	sed -i -e 's:noinst_PROG:check_PROG:' tests/Makefile.am || die
+
+	if ! use test; then
+		sed -i -e '/PKG_CHECK_MODULES(TESTS/d' configure.ac || die
+	fi
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} econf \
+		--disable-static \
+		$(multilib_native_use_enable introspection)
+
+	# work-around gtk-doc out-of-source brokedness
+	if multilib_is_native_abi; then
+		ln -s "${S}"/docs/reference/html docs/reference/html || die
+	fi
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	prune_libtool_files
+
+	mv "${ED}"/usr/bin/{,libnotify-}notify-send #379941
+}
+
+pkg_postinst() {
+	eselect notify-send update ifunset
+}
+
+pkg_postrm() {
+	eselect notify-send update ifunset
+}
diff --git a/x11-libs/libnotify/libnotify-0.7.6.ebuild b/x11-libs/libnotify/libnotify-0.7.6.ebuild
index 65811b082a57..ddcff86bfe81 100644
--- a/x11-libs/libnotify/libnotify-0.7.6.ebuild
+++ b/x11-libs/libnotify/libnotify-0.7.6.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/libnotify-0.7.6.ebuild,v 1.1 2013/09/08 15:24:31 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libnotify/libnotify-0.7.6.ebuild,v 1.2 2014/11/24 02:50:14 tetromino Exp $
 
 EAPI=5
 inherit autotools gnome.org
@@ -8,7 +8,7 @@ inherit autotools gnome.org
 DESCRIPTION="A library for sending desktop notifications"
 HOMEPAGE="http://git.gnome.org/browse/libnotify"
 
-LICENSE="LGPL-2.1"
+LICENSE="LGPL-2.1+"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
 IUSE="+introspection test"
diff --git a/x11-libs/libnotify/metadata.xml b/x11-libs/libnotify/metadata.xml
index dfd071461f7a..2953eb8e0471 100644
--- a/x11-libs/libnotify/metadata.xml
+++ b/x11-libs/libnotify/metadata.xml
@@ -2,8 +2,4 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
   <herd>freedesktop</herd>
-  <use>
-    <flag name='introspection'>Use <pkg>dev-libs/gobject-introspection</pkg> for introspection</flag>
-    <flag name='symlink'>Create symlink from libnotify-notify-send to notify-send</flag>
-  </use>
 </pkgmetadata>