From 122b014491d656b8f1715ff8d32b4c73746afa88 Mon Sep 17 00:00:00 2001
From: Michael Sterrett <mr_bones_@gentoo.org>
Date: Mon, 29 Aug 2005 06:24:03 +0000
Subject: version bump (Portage version: 2.0.51.22-r2)

---
 games-arcade/ceferino/ceferino-0.96.ebuild | 55 ++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 games-arcade/ceferino/ceferino-0.96.ebuild

(limited to 'games-arcade/ceferino/ceferino-0.96.ebuild')

diff --git a/games-arcade/ceferino/ceferino-0.96.ebuild b/games-arcade/ceferino/ceferino-0.96.ebuild
new file mode 100644
index 000000000000..a0c390101d28
--- /dev/null
+++ b/games-arcade/ceferino/ceferino-0.96.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-arcade/ceferino/ceferino-0.96.ebuild,v 1.1 2005/08/29 06:24:03 mr_bones_ Exp $
+
+inherit eutils games
+
+DESCRIPTION="Super-Pang clone (destroy bouncing balloons with your grapnel)"
+HOMEPAGE="http://www.loosersjuegos.com.ar/juegos/ceferino/ceferino.php"
+SRC_URI="http://www.loosersjuegos.com.ar/juegos/ceferino/descargas/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc x86"
+IUSE="nls"
+
+RDEPEND=">=media-libs/libsdl-1.2
+	>=media-libs/sdl-image-1.2
+	>=media-libs/sdl-mixer-1.2"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	sed -i \
+		-e '/^install-data-am/s:install-docDATA::' Makefile.in \
+		|| die "sed failed"
+	sed -i \
+		-e '/^\(gnu\)\?localedir /s:= .*:= /usr/share/locale:' \
+		po/Makefile.in.in src/Makefile.in \
+		|| die "sed failed"
+}
+
+src_compile() {
+	egamesconf $(use_enable nls) || die
+	emake || die "emake failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "make install failed"
+	dodoc AUTHORS ChangeLog README README_ES TODO
+	newicon src/ima/icono.png ${PN}.png
+	make_desktop_entry ceferino "Don Ceferino Hazaña"
+	prepgamesdirs
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	if ! built_with_use media-libs/sdl-mixer mikmod ; then
+		ewarn
+		ewarn "To hear music, you will have to rebuild media-libs/sdl-mixer"
+		ewarn "with the \"mikmod\" USE flag turned on."
+		ewarn
+	fi
+}
-- 
cgit v1.2.3-65-gdbad