# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/gstreamer-editing-services/gstreamer-editing-services-1.4.0.ebuild,v 1.4 2015/03/14 18:48:50 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"

inherit gnome2

DESCRIPTION="SDK for making video editors and more"
HOMEPAGE="http://wiki.pitivi.org/wiki/GES"
SRC_URI="http://gstreamer.freedesktop.org/src/${PN}/${P}.tar.xz"

LICENSE="LGPL-2+"
SLOT="1.0"
KEYWORDS="amd64"
IUSE="+introspection"

# FIXME: There is something odd with pygobject check for >=4.22,
#        check with upstream
COMMON_DEPEND="
	>=dev-libs/glib-2.34:2
	dev-libs/libxml2:2
	>=media-libs/gstreamer-1.4:1.0[introspection?]
	>=media-libs/gst-plugins-base-1.4:1.0[introspection?]
	introspection? ( >=dev-libs/gobject-introspection-0.9.6 )
"
RDEPEND="${COMMON_DEPEND}
	media-libs/gnonlin:1.0
"
DEPEND="${COMMON_DEPEND}
	>=dev-util/gtk-doc-am-1.3
	virtual/pkgconfig
"

src_prepare() {
	# FIXME: disable failing check
	sed -e 's|\(tcase_add_test (.* test_project_load_xges);\)|/*\1*/|' \
		-i "${S}"/tests/check/ges/project.c || die
	gnome2_src_prepare
}

src_configure() {
	# gtk is only used for examples
	gnome2_src_configure \
		$(use_enable introspection) \
		--disable-examples \
		--without-gtk \
	        --with-package-name="GStreamer editing services ebuild for Gentoo" \
        	--with-package-origin="http://packages.gentoo.org/package/media-libs/gstreamer-editing-services"
}

src_compile() {
	# Prevent sandbox violations, bug #538888
	# https://bugzilla.gnome.org/show_bug.cgi?id=744135
	# https://bugzilla.gnome.org/show_bug.cgi?id=744134
	addpredict /dev
	gnome2_src_compile
}