games-emulation/snes9x/snes9x-1.42-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-emulation/snes9x/snes9x-1.42-r1.ebuild,v 1.1 2004/04/14 07:33:50 mr_bones_ Exp $

inherit games

DESCRIPTION="Super Nintendo Entertainment System (SNES) emulator"
HOMEPAGE="http://www.snes9x.com/"
SRC_URI="http://www.lysator.liu.se/snes9x/${PV}/snes9x-${PV}-src.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="x86 ~ppc"
IUSE="3dfx opengl X joystick"

RDEPEND="sys-libs/zlib
	virtual/x11
	media-libs/libpng
	opengl? ( virtual/opengl )
	3dfx? ( media-libs/glide-v3 )"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4
	x86? ( dev-lang/nasm )"

S="${WORKDIR}/${P}-src"

src_unpack() {
	unpack ${A}
	cd "${S}/snes9x"
	epatch "${FILESDIR}/${PV}-system-zlib.patch"
	epatch "${FILESDIR}/nojoy.patch"
}

src_compile() {
	local vidconf=
	local target=
	local vid=

	mkdir mybins
	for vid in 3dfx opengl X ; do
		use ${vid} || continue
		cd "${S}/snes9x"
		case ${vid} in
			3dfx)
				vidconf="--with-glide --without-opengl --without-x"
				target=gsnes9x;;
			opengl)
				vidconf="--with-opengl --without-glide --without-x"
				target=osnes9x;;
			X)
				vidconf="--with-x --without-glide --without-opengl"
				target=snes9x;;
		esac
		# this stuff is ugly but hey the build process sucks ;)
		egamesconf \
			--with-screenshot \
			$(use_with joystick) \
			${vidconf} \
			$(use_with x86 assembler) \
				|| die
		emake ${target} || die "making ${target}"
		mv ${target} "${S}/mybins/"
		cd "${WORKDIR}"
		rm -rf "${S}/snes9x"
		src_unpack
	done
}

src_install() {
	dogamesbin mybins/*
	dodoc faqs.txt readme.txt readme.unix snes9x/*.txt
	prepgamesdirs
}