net-misc/dante/dante-1.1.14-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/dante/dante-1.1.14-r2.ebuild,v 1.1 2003/12/23 10:48:10 robbat2 Exp $

inherit gcc fixheadtails

DESCRIPTION="A free socks4,5 and msproxy implemetation"
HOMEPAGE="http://www.inet.no/dante/"
SRC_URI="ftp://ftp.inet.no/pub/socks/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc ~alpha ~hppa ia64"
IUSE="tcpd debug"

RDEPEND="virtual/glibc
		 sys-libs/pam
		 tcpd? ( sys-apps/tcp-wrappers )"
DEPEND="${RDEPEND}
		>=sys-apps/sed-4"

src_unpack() {
	unpack ${A} || die "unpack failed"
	cd ${S}     || die "cd failed"
	epatch ${FILESDIR}/dante-1.1.14-socksify.patch || die "epatch failed"
	epatch ${FILESDIR}/dante-1.1.14-bindresvport.patch || die "epatch failed"
	ht_fix_file `find ${S} -name 'configure'`
}

src_compile() {
	econf \
		`use_enable debug` \
		`use_enable tcpd libwrap` \
		--with-socks-conf=/etc/socks/socks.conf \
		--with-sockd-conf=/etc/socks/sockd.conf \
		${myconf} \
		|| die "bad ./configure"
	emake || die "compile problem"
}

src_install() {
	make DESTDIR=${D} install || die

	# bor: comment libdl.so out it seems to work just fine without it
	sed -i -e 's:libdl\.so::' ${D}/usr/bin/socksify || die 'sed failed'

	# no configuration file by default
	dodir /etc/socks

	# our init script
	exeinto /etc/init.d
	newexe ${FILESDIR}/dante-sockd-init-1.1.14-r2 dante-sockd
	insinto /etc/conf.d
	newins ${FILESDIR}/dante-sockd-conf-1.1.14-r2 dante-sockd

	# install documentation
	dodoc BUGS CREDITS LICENSE NEWS README SUPPORT TODO VERSION
	docinto txt
	cd doc
	dodoc README* *.txt SOCKS4.*
	docinto example
	cd ../example
	dodoc *.conf
}