# Copyright 2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /home/camp/CVSROOT/CamposEbuilds/portage/sci-calculators/campos-ase/campos-ase-2.1.1.ebuild,v 1.3 2006/02/15 10:27:52 schiotz Exp $

inherit python multilib distutils eutils

PYTHON_MODNAME="ase"
MY_PN="python-ase"
MY_P=${MY_PN}-${PV}
DESCRIPTION="The Atomistic Simulation Environment is the core of the CampOS simulation software.  There are Python modules for: building atomic structures, molecular dynamics, structure optimization, analysis and much more."
HOMEPAGE="http://wiki.fysik.dtu.dk/ase"
SRC_URI="http://dcwww.camp.dtu.dk/campos/download/${MY_P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc X"
RDEPEND="
	>=dev-python/scientificpython-2.4.3
	X? (
		media-gfx/povray
		virtual/ghostscript
	)"
DEPEND="${RDEPEND}
	doc? ( dev-python/epydoc )"
S=${WORKDIR}/${MY_P}

src_compile() {
	distutils_src_compile
	if use doc; then
		# Pythonpath set to work around bug in epydoc
		python_version
		export PYTHONPATH=/usr/$(get_libdir)/python${PYVER}/site-packages/Scientific/linux2
		epydoc --output epydoc --inheritance included --name ASE --url ${HOMEPAGE} ASE
	fi
}

src_test() {
	einfo "Running tests"
	# display=False stops X windows from popping up
	${python} -c 'import ase.test; ase.test.test(display=False)'
}

src_install() {
	distutils_src_install
	use doc && dohtml -r epydoc/*
}