blob: f4e46695eb7d3bd4dd06b09c277f5c485d115c32 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_TEST="forceoptional"
KDE_ORG_CATEGORY="pim"
PVCUT=$(ver_cut 1-3)
KFMIN=6.3.0
QTMIN=6.6.2
inherit ecm gear.kde.org optfeature
DESCRIPTION="Digital travel assistant with a priority on protecting your privacy"
HOMEPAGE="https://apps.kde.org/itinerary/
https://www.volkerkrause.eu/2018/08/19/kde-itinerary-introduction.html"
LICENSE="LGPL-2+"
SLOT="6"
KEYWORDS=""
IUSE="matrix +networkmanager"
DEPEND="
>=dev-libs/kirigami-addons-0.9:6
>=dev-libs/kosmindoormap-${PVCUT}:6
>=dev-libs/kpublictransport-${PVCUT}:6
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
>=dev-qt/qtdeclarative-${QTMIN}:6
>=dev-qt/qtlocation-${QTMIN}:6
>=dev-qt/qtpositioning-${QTMIN}:6[qml]
>=kde-apps/kitinerary-${PVCUT}:6
>=kde-apps/kpkpass-${PVCUT}:6
>=kde-frameworks/kcalendarcore-${KFMIN}:6
>=kde-frameworks/kcontacts-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/kfilemetadata-${KFMIN}:6
>=kde-frameworks/kholidays-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kitemmodels-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kunitconversion-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6
sys-libs/zlib
matrix? ( >=net-libs/libquotient-0.8.1.2-r1:=[qt6] )
networkmanager? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:6 )
"
RDEPEND="${DEPEND}
>=dev-qt/qtmultimedia-${QTMIN}:6[qml]
>=kde-frameworks/kirigami-${KFMIN}:6
>=kde-frameworks/prison-${KFMIN}:6[qml]
"
src_configure() {
local mycmakeargs=(
-DCMAKE_DISABLE_FIND_PACKAGE_SeleniumWebDriverATSPI=ON # not packaged
$(cmake_use_find_package networkmanager KF6NetworkManagerQt)
$(cmake_use_find_package matrix QuotientQt6)
)
ecm_src_configure
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "screen brightness control to aid barcode scanning" "kde-frameworks/solid:6"
fi
ecm_pkg_postinst
}
|
GitWeb
