# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit autotools eutils bash-completion

DESCRIPTION="Linux-VServer admin utilities"
HOMEPAGE="http://www.nongnu.org/util-vserver/"
SRC_URI="http://ftp.linux-vserver.org/pub/utils/${PN}/${P}.tar.bz2
	http://dev.gentoo.org/~hollow/distfiles/${PN}-patches-${PVR}.tar.bz2
	http://dev.gentoo.org/~phreak/distfiles/${PN}-patches-${PVR}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"

IUSE="legacy"

DEPEND=">=dev-libs/dietlibc-0.28
	dev-libs/beecrypt
	net-firewall/iptables
	net-misc/vconfig
	sys-apps/iproute2
	sys-process/procps
	=sys-devel/automake-1.9*"

RDEPEND="sys-apps/iproute2
	net-misc/vconfig
	net-firewall/iptables
	dev-libs/beecrypt
	sys-process/procps"

pkg_setup() {
	if [[ -z "${VDIRBASE}" ]]; then
		einfo
		einfo "You can change the default vserver base directory (/vservers)"
		einfo "by setting the VDIRBASE environment variable."
	fi

	: ${VDIRBASE:=/vservers}

	einfo
	einfo "Using \"${VDIRBASE}\" as vserver base directory"
	einfo

	myconf="${myconf} --with-vrootdir=${VDIRBASE}"

	# default paths
	myconf="${myconf} --localstatedir=/var"
	myconf="${myconf} --with-initrddir=/etc/init.d"

	# needed for older vserver kernels not in portage (default: v13,net)
	# we provide this just for convenience for people using self-made kernels
	use legacy && myconf="${myconf} --enable-apis=compat,v11,fscompat,v13,net"
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${WORKDIR}"/patches/*.patch

	eautomake
}

src_compile() {
	econf ${myconf} || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install install-distribution || die "install failed"

	# remove non-legacy files
	if ! use legacy ; then
		rm -r -f "${D}/etc/vservers.conf"
		rm -r -f "${D}/usr/lib/util-vserver/legacy"
		rm -r -f "${D}/usr/sbin/vserver-copy"
		rm -r -f "${D}/usr/share/man/man8/distrib-info.8.gz"
		rm -r -f "${D}/usr/share/man/man8/vps.8.gz"
	fi

	# keep dirs
	keepdir /var/run/{vservers,vservers.rev,vshelper}
	keepdir /var/lock/vservers
	keepdir /var/cache/vservers

	keepdir "${VDIRBASE}"

	# remove the non-gentoo init-scripts:
	rm -f "${D}"/etc/init.d/*

	# and install branded/customized init-scripts:
	doinitd "${WORKDIR}"/init.d/v* || die "Failed to ins init.d/v*"
	doconfd "${WORKDIR}"/conf.d/vservers || die "Failed to ins conf.d/vservers"

	# bash-completion
	dobashcompletion "${S}"/contrib/bash_completion util-vserver

	dodoc README ChangeLog NEWS AUTHORS THANKS util-vserver.spec
}

pkg_postinst() {
	einfo
	einfo "You have to run the vprocunhide command after every reboot"
	einfo "in order to setup /proc permissions correctly for vserver"
	einfo "use. An init script has been installed by this package."
	einfo "To use it you should add it to a runlevel:"
	einfo
	einfo " rc-update add vprocunhide default"
	einfo
	ewarn
	ewarn "You should definitly fix up the barrier of your vserver"
	ewarn "base directory by using the following command in a root shell:"
	ewarn
	ewarn " setattr --barrier ${VDIRBASE}"
	ewarn
	if has_version "<0.30.211-r1" ; then
		ewarn "IMPORTANT UPGRADE WARNING:"
		ewarn
		ewarn "Since 0.30.211-r1 the vservers init-script has been split"
		ewarn "into vprocunhide and vserver.defaults. The following steps"
		ewarn "are required to keep current behaviour:"
		ewarn
		ewarn " rc-update del vservers"
		ewarn " rc-update add vprocunhide default"
		ewarn " rc-update add vservers.default default"
		ewarn
	fi
}