media-gfx/pqiv: version bump to 2.9

4 files changed, 101 insertions, 15 deletions

diff --git a/media-gfx/pqiv/Manifest b/media-gfx/pqiv/Manifest
index 7975c57dc0cb..3f3a24e7ad8b 100644
--- a/media-gfx/pqiv/Manifest
+++ b/media-gfx/pqiv/Manifest
@@ -1 +1,2 @@
 DIST pqiv-2.8.5.tar.gz 108686 SHA256 7895fe0cb7b18d9e40d0353df2ec964aed4e1bb7fa7e1ea9a1e00858d3a89ce9 SHA512 dc3a7a49a781002e9234982405b3a3633673b523ab4db1dbe52b2ad3f3a859920f3087f0f492df5a54560c7048b5587bf976ae37db86669ba5941b81c2f21906 WHIRLPOOL 05077b650dd739634ab3b21086f926b12e6fe01b2c047d497241fd1a5cba4da22cc9ae68e560613b3eedefe0f90e76164aebe001981c136a11601ad852faebe3
+DIST pqiv-2.9.tar.gz 133823 SHA256 e57298ae7123bd6b01b751f6ef2d7a7853e731a3271b50095683442a406da99c SHA512 0a509d5d4b41682f86f4b813d63f3f7f8f3977ede0b8b1649a2adc188ed83923147b8bb741ba7f85b4c1dd7a9612fca3fec44169364042be4db44ef53d813ab7 WHIRLPOOL e40e4aab7b4df92cc7bed911531be4e84062196ca1fdae867b05da38f28c448a34475a31865275f0d38f3efedf1f07af42f305fcb6621a16a73f7050cb327652
diff --git a/media-gfx/pqiv/pqiv-2.8.5.ebuild b/media-gfx/pqiv/pqiv-2.8.5.ebuild
index 5b0851c1aca6..d3b8017191ca 100644
--- a/media-gfx/pqiv/pqiv-2.8.5.ebuild
+++ b/media-gfx/pqiv/pqiv-2.8.5.ebuild
@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
-inherit linux-info toolchain-funcs fdo-mime
+inherit linux-info toolchain-funcs xdg-utils
 
 if [[ ${PV} == 9999 ]]; then
 	EGIT_REPO_URI="https://github.com/phillipberndt/pqiv.git"
@@ -65,9 +65,9 @@ src_compile() {
 }
 
 pkg_postinst() {
-	fdo-mime_desktop_database_update
+	xdg_desktop_database_update
 }
 
 pkg_postrm() {
-	fdo-mime_desktop_database_update
+	xdg_desktop_database_update
 }
diff --git a/media-gfx/pqiv/pqiv-2.9.ebuild b/media-gfx/pqiv/pqiv-2.9.ebuild
new file mode 100644
index 000000000000..38325520298a
--- /dev/null
+++ b/media-gfx/pqiv/pqiv-2.9.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit linux-info toolchain-funcs xdg-utils
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/phillipberndt/pqiv.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/phillipberndt/pqiv/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="powerful GTK 3 based command-line image viewer with a minimal UI"
+HOMEPAGE="https://github.com/phillipberndt/pqiv http://www.pberndt.com/Programme/Linux/pqiv/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="archive ffmpeg imagemagick kernel_linux libav pdf postscript webp"
+
+RDEPEND="
+	>=dev-libs/glib-2.8:2
+	>=x11-libs/cairo-1.6
+	x11-libs/gtk+:3
+	archive? ( app-arch/libarchive:0= )
+	ffmpeg? (
+		!libav? ( media-video/ffmpeg:0= )
+		libav? ( media-video/libav:0= )
+	)
+	imagemagick? ( media-gfx/imagemagick:0= )
+	pdf? ( app-text/poppler:0= )
+	postscript? ( app-text/libspectre:0= )
+	webp? ( media-libs/libwebp:0= )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+doecho() {
+	echo "$@"
+	"$@" || die
+}
+
+pkg_setup() {
+	if use kernel_linux; then
+		CONFIG_CHECK="~INOTIFY_USER"
+		linux-info_pkg_setup
+	fi
+}
+
+src_configure() {
+	local backends="gdkpixbuf"
+	use archive && backends+=",archive,archive_cbx"
+	use ffmpeg || use libav && backends+=",libav"
+	use imagemagick && backends+=",wand"
+	use pdf && backends+=",poppler"
+	use postscript && backends+=",spectre"
+	use webp && backends+=",webp"
+
+	doecho ./configure \
+		--backends-build=shared \
+		--backends=${backends} \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--destdir="${ED}"
+}
+
+src_compile() {
+	tc-export CC
+	emake VERBOSE=1 CFLAGS="${CFLAGS}"
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}
diff --git a/media-gfx/pqiv/pqiv-9999.ebuild b/media-gfx/pqiv/pqiv-9999.ebuild
index 4c3939b69e11..38325520298a 100644
--- a/media-gfx/pqiv/pqiv-9999.ebuild
+++ b/media-gfx/pqiv/pqiv-9999.ebuild
@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
-inherit linux-info toolchain-funcs fdo-mime
+inherit linux-info toolchain-funcs xdg-utils
 
 if [[ ${PV} == 9999 ]]; then
 	EGIT_REPO_URI="https://github.com/phillipberndt/pqiv.git"
@@ -17,7 +17,7 @@ HOMEPAGE="https://github.com/phillipberndt/pqiv http://www.pberndt.com/Programme
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="archive ffmpeg imagemagick kernel_linux libav pdf postscript"
+IUSE="archive ffmpeg imagemagick kernel_linux libav pdf postscript webp"
 
 RDEPEND="
 	>=dev-libs/glib-2.8:2
@@ -31,10 +31,16 @@ RDEPEND="
 	imagemagick? ( media-gfx/imagemagick:0= )
 	pdf? ( app-text/poppler:0= )
 	postscript? ( app-text/libspectre:0= )
+	webp? ( media-libs/libwebp:0= )
 "
 DEPEND="${RDEPEND}
 	virtual/pkgconfig"
 
+doecho() {
+	echo "$@"
+	"$@" || die
+}
+
 pkg_setup() {
 	if use kernel_linux; then
 		CONFIG_CHECK="~INOTIFY_USER"
@@ -44,19 +50,19 @@ pkg_setup() {
 
 src_configure() {
 	local backends="gdkpixbuf"
-	use archive && backends="${backends},archive,archive_cbx"
-	use ffmpeg || use libav && backends="${backends},libav"
-	use imagemagick && backends="${backends},wand"
-	use pdf && backends="${backends},poppler"
-	use postscript && backends="${backends},spectre"
+	use archive && backends+=",archive,archive_cbx"
+	use ffmpeg || use libav && backends+=",libav"
+	use imagemagick && backends+=",wand"
+	use pdf && backends+=",poppler"
+	use postscript && backends+=",spectre"
+	use webp && backends+=",webp"
 
-	./configure \
+	doecho ./configure \
 		--backends-build=shared \
 		--backends=${backends} \
 		--prefix="${EPREFIX}/usr" \
 		--libdir="${EPREFIX}/usr/$(get_libdir)" \
-		--destdir="${ED}" \
-		|| die
+		--destdir="${ED}"
 }
 
 src_compile() {
@@ -65,9 +71,9 @@ src_compile() {
 }
 
 pkg_postinst() {
-	fdo-mime_desktop_database_update
+	xdg_desktop_database_update
 }
 
 pkg_postrm() {
-	fdo-mime_desktop_database_update
+	xdg_desktop_database_update
 }