dev-python/pastescript: Fix namespace support

1 files changed, 59 insertions, 0 deletions

diff --git a/dev-python/pastescript/pastescript-2.0.2-r1.ebuild b/dev-python/pastescript/pastescript-2.0.2-r1.ebuild
new file mode 100644
index 000000000000..3f7ec1a0e220
--- /dev/null
+++ b/dev-python/pastescript/pastescript-2.0.2-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_4 )
+
+inherit distutils-r1
+
+MY_PN="PasteScript"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A pluggable command-line frontend, including commands to setup package file layouts"
+HOMEPAGE="http://pythonpaste.org/script/ https://pypi.python.org/pypi/PasteScript"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/namespace-paste[${PYTHON_USEDEP}]
+	>=dev-python/paste-1.3[${PYTHON_USEDEP}]
+	dev-python/pastedeploy[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/pygments[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		)
+	test? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+# Tests are broken.
+RESTRICT="test"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	if use doc; then
+		einfo "Generation of documentation"
+		esetup.py build_sphinx
+	fi
+}
+
+python_test() {
+	nosetests -v -v || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use doc; then
+		cd "${BUILD_DIR}"/sphinx/html || die
+		dohtml -r [a-z]* _static
+	fi
+
+	find "${D}" -name '*.pth' -delete || die
+}