kde-apps/kalarm: 22.08.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/kde-apps/kalarm/Manifest b/kde-apps/kalarm/Manifest
index af8e72ff9618..a890b06cd1a2 100644
--- a/kde-apps/kalarm/Manifest
+++ b/kde-apps/kalarm/Manifest
@@ -1,2 +1,3 @@
 DIST kalarm-22.04.3.tar.xz 2347752 BLAKE2B 9749172b9246c0f903ccbf7fd6ca7dae756ac9cfab594a85cc0cdff772dc0f0c21b48b2f2c0ff71467b117f0e287def9c4202a033636ce93f1317a567ff8e017 SHA512 22650e5263d0a7bb584da138977da32cad38672f2e2dd2beb5ad1b9f31f76cbed68fd3b9ca5c241bacbc793ce5102da5b331b68e689868620f46aab2234d26c4
 DIST kalarm-22.08.2.tar.xz 2371348 BLAKE2B a0ec9645af3f22707414a3049b33499f213c3c44a780ea5ec664a89f13b9201c6190fca8dbeec666a4d4b48e9dbacff33d3e2580ef213b33fb39444249e83844 SHA512 4b1d7b50f64bee4681838cdfc8eeaaa1def29c31ec175d64d02388c942fc5fdc911295753c5d282cd60fcbbf122ae36d35c0675fec192538d761b8370bcd9a2a
+DIST kalarm-22.08.3.tar.xz 2371056 BLAKE2B 0b6fb3e8c6e8c8433e89efa276ec5d9a5513b1c9ad2421fc172102a3c5e08f5650c50e8fe08666089b8f2d6366676397803c06c9c5812aa33c519389dc8cf554 SHA512 eeda0f3938ce13ba5e36242cc6401a3df46ab2acc5bf2d57d68268944c863d3b5c4f4667d4d082b08fa8f4d0928f5e343e9fdea392562200f365180289f1a549
diff --git a/kde-apps/kalarm/kalarm-22.08.3.ebuild b/kde-apps/kalarm/kalarm-22.08.3.ebuild
new file mode 100644
index 000000000000..441327177a16
--- /dev/null
+++ b/kde-apps/kalarm/kalarm-22.08.3.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.96.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Application to manage alarms and other timer based alerts for the desktop"
+HOMEPAGE="https://apps.kde.org/kalarm/ https://userbase.kde.org/KAlarm"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+pim speech X"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/kcalutils-${PVCUT}:5
+	>=kde-apps/kidentitymanagement-${PVCUT}:5
+	>=kde-apps/kmime-${PVCUT}:5
+	>=kde-apps/kontactinterface-${PVCUT}:5
+	>=kde-apps/kpimtextedit-${PVCUT}:5[speech=]
+	>=kde-apps/pimcommon-${PVCUT}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcalendarcore-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcontacts-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/kholidays-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5[X?]
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=media-libs/phonon-4.11.0
+	pim? (
+		>=kde-apps/akonadi-${PVCUT}:5
+		>=kde-apps/akonadi-contacts-${PVCUT}:5
+		>=kde-apps/akonadi-mime-${PVCUT}:5
+		>=kde-apps/kmailtransport-${PVCUT}:5
+	)
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}
+	!kde-apps/kalarmcal:5
+	pim? ( >=kde-apps/kdepim-runtime-${PVCUT}:5 )
+"
+
+PATCHES=( "${FILESDIR}/${PN}-22.07.90-without_x11.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_AKONADI_PLUGIN=$(usex pim)
+		-DWITHOUT_X11=$(usex !X)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# LC_TIME bug 665626, 857012
+	# TZ bug https://bugs.kde.org/show_bug.cgi?id=445734
+	LC_TIME="C" TZ=UTC ecm_src_test
+}