kde-apps/kalarm: 21.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 81 insertions, 0 deletions

diff --git a/kde-apps/kalarm/Manifest b/kde-apps/kalarm/Manifest
index 8bd95204a3ad..89da16c8a6ce 100644
--- a/kde-apps/kalarm/Manifest
+++ b/kde-apps/kalarm/Manifest
@@ -1 +1,2 @@
 DIST kalarm-21.08.3.tar.xz 2158988 BLAKE2B 45e544bc518a0640760a0af329983ab6b052fcc0cbba43beff5963018cdd4992053aec6fac506784fe826b626591218eb24bb654402e7a00ae009b5234b54d83 SHA512 690c89006598e8e87e1fd4b0f9b5d183280efa3f5f2d1fcda01607498b03ffad75a60e49ef4435f8fd66357231446c187a77d9976a6c04d98519f8ca3747a1b7
+DIST kalarm-21.12.0.tar.xz 2159796 BLAKE2B c891ccd4645ca8633ff94c5734bc8371054c34416d16991a5a61540a3ab309fd84a7b11393ca00ec964b7ebf275b563fb1981b433e8ae55629346e6a28d2a4f8 SHA512 c302b921808e47dd29f65b4bc82c4f49a3c998efaf4d3483d577ddd826f96ff82f08159c0e027f0a3a1b42e18d5936679c78b7eadd6eade57b9937ca79dbc8a1
diff --git a/kde-apps/kalarm/kalarm-21.12.0.ebuild b/kde-apps/kalarm/kalarm-21.12.0.ebuild
new file mode 100644
index 000000000000..a228c704f7fe
--- /dev/null
+++ b/kde-apps/kalarm/kalarm-21.12.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.88.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Application to manage alarms and other timer based alerts for the desktop"
+HOMEPAGE="https://apps.kde.org/kalarm/ https://userbase.kde.org/KAlarm"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="X"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/akonadi-${PVCUT}:5
+	>=kde-apps/akonadi-contacts-${PVCUT}:5
+	>=kde-apps/akonadi-mime-${PVCUT}:5
+	>=kde-apps/kalarmcal-${PVCUT}:5
+	>=kde-apps/kcalutils-${PVCUT}:5
+	>=kde-apps/kidentitymanagement-${PVCUT}:5
+	>=kde-apps/kmailtransport-${PVCUT}:5
+	>=kde-apps/kmime-${PVCUT}:5
+	>=kde-apps/kontactinterface-${PVCUT}:5
+	>=kde-apps/kpimtextedit-${PVCUT}:5
+	>=kde-apps/pimcommon-${PVCUT}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcalendarcore-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcontacts-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/kholidays-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=media-libs/phonon-4.11.0
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/kdepim-runtime-${PVCUT}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package X Qt5X11Extras)
+		$(cmake_use_find_package X X11)
+	)
+
+	ecm_src_configure
+}