kde-apps/kio-extras: revision bump to resolve CVE-2018-19120

Bug: https://bugs.gentoo.org/671316
Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Michael Palimaka <kensington@gentoo.org>

1 files changed, 77 insertions, 0 deletions

diff --git a/kde-apps/kio-extras/kio-extras-18.04.3-r1.ebuild b/kde-apps/kio-extras/kio-extras-18.04.3-r1.ebuild
new file mode 100644
index 000000000000..842ba65606a4
--- /dev/null
+++ b/kde-apps/kio-extras/kio-extras-18.04.3-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="optional"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="KIO plugins present a filesystem-like view of arbitrary data"
+HOMEPAGE="https://cgit.kde.org/kio-extras.git"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="activities +man mtp openexr phonon samba +sftp taglib"
+
+COMMON_DEPEND="
+	$(add_frameworks_dep karchive 'bzip2,lzma')
+	$(add_frameworks_dep kbookmarks)
+	$(add_frameworks_dep kcodecs)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kdnssd)
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kparts)
+	$(add_frameworks_dep kpty)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtsvg)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	activities? (
+		$(add_frameworks_dep kactivities)
+		$(add_qt_dep qtsql)
+	)
+	man? ( $(add_frameworks_dep khtml) )
+	mtp? ( media-libs/libmtp:= )
+	openexr? ( media-libs/openexr )
+	phonon? ( media-libs/phonon[qt5(+)] )
+	samba? ( net-fs/samba[client] )
+	sftp? ( net-libs/libssh:=[sftp] )
+	taglib? ( >=media-libs/taglib-1.11.1 )
+"
+RDEPEND="${COMMON_DEPEND}
+	$(add_frameworks_dep kded)
+"
+DEPEND="${COMMON_DEPEND}
+	x11-misc/shared-mime-info
+	man? ( dev-util/gperf )
+"
+
+# requires running kde environment
+RESTRICT+=" test"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebEngineWidgets=ON
+		$(cmake-utils_use_find_package activities KF5Activities)
+		$(cmake-utils_use_find_package man Gperf)
+		$(cmake-utils_use_find_package mtp Mtp)
+		$(cmake-utils_use_find_package openexr OpenEXR)
+		$(cmake-utils_use_find_package phonon Phonon4Qt5)
+		$(cmake-utils_use_find_package samba Samba)
+		$(cmake-utils_use_find_package sftp LibSSH)
+		$(cmake-utils_use_find_package taglib Taglib)
+	)
+
+	kde5_src_configure
+}