net-wireless/blueman: Bump to 2.1.alpha1

2 files changed, 126 insertions, 0 deletions

diff --git a/net-wireless/blueman/Manifest b/net-wireless/blueman/Manifest
index ac635fd5a4bc..05210a2c1471 100644
--- a/net-wireless/blueman/Manifest
+++ b/net-wireless/blueman/Manifest
@@ -1,2 +1,3 @@
 DIST blueman-2.0.3.tar.xz 1942832 SHA256 243605e4401c2d21f4706965ef100dac907658d480ace37cbdf863c1c8a45825 SHA512 aaa6bad3321102b09f1cf69f0a3bc7d848bb6674821aa3cb6848243efcd1c1a2b37e20118bf8368b22e32ed1066b57ff187d3a672f2e41122c82d6526bfc888a WHIRLPOOL 0e5ede56e64287e7d500a1836a3eea21efd4f6b1dedd9c5376179309279ecd3d7e84e622c2d167ec5eadc1801c83303c0f2a3988f9eca3422302344414e348d9
 DIST blueman-2.0.4.tar.xz 1951988 SHA256 e92dd9c27f75a1485b548f7a8b159946a4af154b90fb82f5a0f614b66a01430f SHA512 98dbe0ac706cf8d33ada6e520c0952fbb930aaa4ec62e35e989f60880287634c2ee947a47b4883063a0aabf27069210774432416278b190b1ca5e1c93d42f614 WHIRLPOOL 13bc27b281b0d17610ac974b46b6d4a290276aa3c8238e6768b763f998ec1bd34af4aa4ea199307ff2d50d4b886e1ea2931a6be6795e68e390d7df7548c48fc8
+DIST blueman-2.1.alpha1.tar.xz 1958092 SHA256 df48a28e68117065c00215b6a1060467c80f0cb5ddc2989ea4818c9e78d62909 SHA512 a9180e2cd9596c4e0bde497b0ddf62514dc232d944433f4ae365bc0249a2dd0524bdc9907fbffe604fcb7479fd7b504f304e53688cc552cf7c9184b94413784c WHIRLPOOL 2dc349e6f91db30f5d0c90dec5fdb5dfdcecaacfc2db6ea000726f17b52a01fd6813794cb83588e874eb15b542c8f2404aeb51e1deb97a31419f97750b55190b
diff --git a/net-wireless/blueman/blueman-2.1_alpha1.ebuild b/net-wireless/blueman/blueman-2.1_alpha1.ebuild
new file mode 100644
index 000000000000..d9f1dd4e1051
--- /dev/null
+++ b/net-wireless/blueman/blueman-2.1_alpha1.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+inherit gnome2-utils linux-info python-single-r1 systemd
+
+DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
+HOMEPAGE="https://github.com/blueman-project/blueman"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/blueman-project/blueman.git"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/blueman-project/${PN}/releases/download/${PV/_/.}/${P/_/.}.tar.xz"
+	KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="appindicator network nls policykit pulseaudio thunar"
+
+COMMON_DEPEND="
+	dev-python/pygobject:3
+	>=net-wireless/bluez-5:=
+	${PYTHON_DEPS}"
+DEPEND="${COMMON_DEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	nls? ( dev-util/intltool sys-devel/gettext )"
+RDEPEND="${COMMON_DEPEND}
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	sys-apps/dbus
+	x11-libs/gtk+:3[introspection]
+	x11-libs/libnotify[introspection]
+	|| (
+		x11-themes/faenza-icon-theme
+		x11-themes/gnome-icon-theme
+		x11-themes/mate-icon-theme
+	)
+	appindicator? ( dev-libs/libappindicator:3[introspection] )
+	network? (
+		net-firewall/iptables
+		sys-apps/net-tools
+		|| (
+			net-dns/dnsmasq
+			net-misc/dhcp
+			>=net-misc/networkmanager-0.8
+		)
+	)
+	policykit? ( sys-auth/polkit )
+	pulseaudio? ( media-sound/pulseaudio[bluetooth] )
+	thunar? ( xfce-base/thunar )
+	!net-wireless/gnome-bluetooth
+"
+
+S=${WORKDIR}/${P/_/.}
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+pkg_pretend() {
+	if use network; then
+		local CONFIG_CHECK="~BRIDGE ~IP_NF_IPTABLES
+			~IP_NF_NAT ~IP_NF_TARGET_MASQUERADE"
+		linux-info_pkg_setup
+	fi
+}
+
+pkg_setup() {
+	pkg_pretend
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--docdir=/usr/share/doc/${PF}
+		--disable-runtime-deps-check
+		--disable-static
+		# TODO: replace upstream with sane system/user unitdir getters
+		--with-systemdunitdir="$(systemd_get_utildir)"
+		$(use_enable appindicator)
+		$(use_enable policykit polkit)
+		$(use_enable nls)
+		$(use_enable pulseaudio)
+		$(use_enable thunar thunar-sendto)
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	if use policykit; then
+		# Allow users in plugdev group to modify connections
+		insinto /usr/share/polkit-1/rules.d
+		doins "${FILESDIR}/01-org.blueman.rules"
+	fi
+
+	python_fix_shebang "${D}"
+	rm "${D}"/$(python_get_sitedir)/*.la || die
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}