sys-kernel/gentoo-kernel-bin: bump to 5.10.27 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 28cff24c2eca..9fd0334335e1 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -35,6 +35,7 @@ DIST gentoo-kernel-5.10.26-1.amd64.xpak 64108960 BLAKE2B 704436ea8e692dc3d646b8f
 DIST gentoo-kernel-5.10.26-1.arm64.xpak 59322442 BLAKE2B 98e0be8da3142cf40d78b9ac7884781ae2832bb1f0ec134b21aaeeba61454de947990a64de66dcabcd7b9beacd650b37a2376571fb43a8a1aa9a522dc57690a8 SHA512 1471461a15bff406151126cd65f158bc7f6aed993d6afea19780c7de3e620fae43283a630e8100c58dee09507e928605dee18817528beb43e1b1dc6450f2b1cb
 DIST gentoo-kernel-5.10.26-1.x86.xpak 57063604 BLAKE2B 51802d43ac1e7f8e36aa7aff4abc3a1d6924aa01f9210f5fdbfd0573b2c37ae2f9a57b7bb275af3bf51bc1846cf409667ec0b1b7659ac9de1f07811d8680b8c0 SHA512 0c6f362201e64f3e07b5dde92e518af613496009edbceea3973a42ecabb817a36053869fe37fdd96078b2ee2532c414239e15f7aabd335c607c421b5e8029ab2
 DIST gentoo-kernel-5.10.27-1.amd64.xpak 64103968 BLAKE2B 68f1d8dda132b7e808f2becb52f9b035c12f4ad6a353bfa51618ec2ba24f527a5c1c3f4244b1cd1418cc34041d4114703e44c98cacd9aab13aa3e7e9941d2abe SHA512 c5eba8f18288936e621956248b3021c7d3c25c0a598ac1f7301287e2ae5bbef29c45d29f0b8b347dff99dc0b9408fbb299162998f4c7d85f330aa5526e4a6eeb
+DIST gentoo-kernel-5.10.27-1.arm64.xpak 59322840 BLAKE2B 35b4da2456931ff3316cf424448991c96d580dc7d63c6211f72b630ec40b27afa684c3e471995ace7d33c535e61c3bcb2443bef6a780b7ce1450e9e3abe7825f SHA512 c3465d647975785093fac8812d4cf2e7be9e4ee0c13afeb92ace0c93f54559c030ef5b746e169ec362b53d9d5df1bcb6c3aa9869acdda56c792803fc3ccde7c5
 DIST gentoo-kernel-5.10.27-1.x86.xpak 57074563 BLAKE2B ec113b1cd361f46d948004f58b0cc81edcc96d68fc5e949a6f4c0d4c634189ad014de8fa028d9282c89f8e75ccacb95034c0e01db21f465931e2ba78ee81f7ea SHA512 c1892e2fa4db321572f76f92231e9f5b3fa4a88a8af17fa5d4f8d754dd565c40eaa8f83dd2e991ab5837d821abe5d7f012fd56cd793f6e0fd6b3f2f78dab1621
 DIST gentoo-kernel-5.11.10-1.amd64.xpak 64501303 BLAKE2B d1bd941d62520fe0a2b7156a56ba43f2123ae758804c361d3953f88ed01079a8d9925770d9f3a7485326fce555824c31fd1ac1e646f8134565228c04e36c94e9 SHA512 b54e2f095933d34c795e4a3d239c77db09fa0392db89252775d4ce7b04fc4f0e1129a45ff65f5de352dfdcb7439659ec17893d9891be69ce127858ea112b0b38
 DIST gentoo-kernel-5.11.10-1.arm64.xpak 59801228 BLAKE2B 1ce4d7955ad3d32abe57ac01f008d7dd8b811fad2658c09b03069bad693d9b653262e0c69abfa65ff1ee2a2117cfc92427c644de53971fa70ce4b99fd360a28e SHA512 2375505cf7ff4ddeed3f352049fd6b041b3449e9cf021fdd8bd59d7661ac17434a75e5e3aef85134185a50ec5832b11a260ad4f4e395ab3d6db4b95664b041ab
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.27-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.27-r1.ebuild
new file mode 100644
index 000000000000..8198cf5ace09
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.27-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}