sys-power/suspend: patchlevel bump

Fixes:
- build with -fcommon / gcc-10
- size_t format warnings

Closes: https://bugs.gentoo.org/721972
Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Andrew Savchenko <bircoph@gentoo.org>

2 files changed, 60 insertions, 0 deletions

diff --git a/sys-power/suspend/Manifest b/sys-power/suspend/Manifest
index b3200f4a3fd2..885d0e20e121 100644
--- a/sys-power/suspend/Manifest
+++ b/sys-power/suspend/Manifest
@@ -1,2 +1,3 @@
 DIST suspend-1.0_p20120915.tar.xz 111080 BLAKE2B 99eea1d9808219373501001f0af90973c9176c1b19d62bff7be26886b11ebb514134b68434e9b453146ef1a4af2c4cc8e26326b956a1b2378c38c100638af17c SHA512 bb714b4a7c0f5749c4b711a5c38ca5d8cb5078176a75387957123f75cfe8348adc3aa4e96335eb65c14ad1dd2f99fd6dbca3b415525dd39b3c547f9b13b775be
 DIST suspend-1.0_p20190605.patch.xz 6224 BLAKE2B 0eefbef5a8d777590f69c85b02edb5575a357b373b78d94846e2c2bd59430cbd55af59ee0e676faa7f60388cb3910adb2182dedadb1fdc1df38a409411ea2df1 SHA512 cf576a029b35306368cbdabb9863965e055198920b86eab7205083f3502ae69ec3e8a4267fb6ceaaf1560a8bdb0c59543453f1baad4758c8adc4ac4ae92736bc
+DIST suspend-1.0_p20200924.patch.xz 6664 BLAKE2B 8a0529859cfd1a19f52fb46f306111ec4e520c9678113fd7c5ad12ada85bed89fedeeafee5145f11f07ef8dac1c6c1ae0ff2d6c6d6f794c268759d70895b1af9 SHA512 27c7cfcf2b2a0f8ccafd4c0020c1dce3aa1df352adac81ba5f24b76381a833f10621f7ae58e55c7c3d41f41ba63a38aa818454edaa32ad1f0fdc6db45b5bfe73
diff --git a/sys-power/suspend/suspend-1.0_p20200924.ebuild b/sys-power/suspend/suspend-1.0_p20200924.ebuild
new file mode 100644
index 000000000000..e40e3e8d371b
--- /dev/null
+++ b/sys-power/suspend/suspend-1.0_p20200924.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+BASE_PV="1.0_p20120915"
+
+DESCRIPTION="Userspace Software Suspend and S2Ram"
+HOMEPAGE="http://suspend.sourceforge.net
+https://github.com/bircoph/suspend"
+SRC_URI="https://dev.gentoo.org/~bircoph/distfiles/${PN}-${BASE_PV}.tar.xz
+	https://dev.gentoo.org/~bircoph/patches/${P}.patch.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="crypt +lzo threads"
+
+RDEPEND="
+	dev-libs/libx86
+	>=sys-apps/pciutils-2.2.4
+	crypt? (
+		>=dev-libs/libgcrypt-1.6.3:0[static-libs]
+		dev-libs/libgpg-error[static-libs] )
+	lzo? ( >=dev-libs/lzo-2[static-libs] ) "
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-lang/perl-5.10
+	virtual/pkgconfig"
+
+S="${WORKDIR}/${PN}"
+
+PATCHES=( "${WORKDIR}/${P}.patch" )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-fbsplash \
+		$(use_enable crypt encrypt) \
+		$(use_enable lzo compress) \
+		$(use_enable threads)
+}
+
+src_install() {
+	dodir etc
+	emake DESTDIR="${D}" install
+	rm "${D}/usr/share/doc/${PF}"/COPYING* || die
+}
+
+pkg_postinst() {
+	elog "In order to make this package work with genkernel see:"
+	elog "https://bugs.gentoo.org/show_bug.cgi?id=156445"
+}