Revert "x11-drivers/xf86-video-ati: port to EAPI 7"

In the port to EAPI=7, we stopped inheriting xorg-2 since that eclass is
not EAPI 7 ready. Unfortunately it was providing some critical
functionality:

[[ ${PN} == xf86-video-* || ${PN} == xf86-input-* ]] && DRIVER="yes"
...
xorg-2_flags_setup() {
...
    [[ ${PN} = xorg-server || -n ${DRIVER} ]] && append-ldflags -Wl,-z,lazy

In order to revert this commit, we must revert some commits that fix
problems introduced by it as well. In total:

This reverts commit f81770e41df51ad850fa78d6f57d7972a9e536bf.

Revert "x11-drivers/xf86-video-ati: Fix QA syntax errors"

This reverts commit 3339c825251a9809d573a98b94f36befe3286de9.

Revert "x11-drivers/xf86-video-ati: fix xorg-server:= dependency"

This reverts commit 6d94f4276b3cc284014af3177e0bc35168315b30.

Revert "x11-drivers/xf86-video-ati: add --disable-selective-werror"

This reverts commit 3313b2661bef1e56f0d089cc5b2c6f2d470fb6be.

Closes: https://bugs.gentoo.org/661562

2 files changed, 13 insertions, 105 deletions

diff --git a/x11-drivers/xf86-video-ati/xf86-video-ati-18.0.1-r2.ebuild b/x11-drivers/xf86-video-ati/xf86-video-ati-18.0.1-r2.ebuild
deleted file mode 100644
index 1ac62fccd4ec..000000000000
--- a/x11-drivers/xf86-video-ati/xf86-video-ati-18.0.1-r2.ebuild
+++ /dev/null
@@ -1,68 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit linux-info
-
-DESCRIPTION="ATI video driver"
-HOMEPAGE="https://www.x.org/wiki/ati/"
-
-if [[ ${PV} == 9999* ]]; then
-	EGIT_REPO_URI="https://anongit.freedesktop.org/git/xorg/driver/${PN}"
-	inherit autotools git-r3
-	LIVE_DEPEND=">=x11-misc/util-macros-1.18"
-else
-	SRC_URI="mirror://xorg/driver/${P}.tar.bz2"
-	KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
-fi
-
-LICENSE="MIT"
-SLOT="0"
-IUSE="+glamor udev"
-
-BDEPEND="
-	virtual/pkgconfig
-"
-RDEPEND="
-	>=x11-libs/libdrm-2.4.78[video_cards_radeon]
-	>=x11-libs/libpciaccess-0.8.0
-	x11-base/xorg-server:=
-	glamor? ( x11-base/xorg-server[glamor] )
-	udev? ( virtual/libudev:= )
-"
-DEPEND="
-	${LIVE_DEPEND}
-	${RDEPEND}
-	x11-base/xorg-proto
-"
-
-pkg_pretend() {
-	if use kernel_linux ; then
-		if kernel_is -ge 3 9; then
-			CONFIG_CHECK="~!DRM_RADEON_UMS ~!FB_RADEON"
-		else
-			CONFIG_CHECK="~DRM_RADEON_KMS ~!FB_RADEON"
-		fi
-	fi
-	check_extra_config
-}
-
-src_prepare() {
-	default
-	[[ ${PV} == 9999 ]] && eautoreconf
-}
-
-src_configure() {
-	local econfargs=(
-		--disable-selective-werror
-		$(use_enable glamor)
-		$(use_enable udev)
-	)
-	econf "${econfargs[@]}"
-}
-
-src_install() {
-	default
-	find "${D}" -name '*.la' -delete || die
-}
diff --git a/x11-drivers/xf86-video-ati/xf86-video-ati-9999.ebuild b/x11-drivers/xf86-video-ati/xf86-video-ati-9999.ebuild
index 1ac62fccd4ec..3f5390aec7a0 100644
--- a/x11-drivers/xf86-video-ati/xf86-video-ati-9999.ebuild
+++ b/x11-drivers/xf86-video-ati/xf86-video-ati-9999.ebuild
@@ -1,41 +1,28 @@
 # Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=5
 
-inherit linux-info
-
-DESCRIPTION="ATI video driver"
-HOMEPAGE="https://www.x.org/wiki/ati/"
+XORG_DRI=always
+inherit linux-info xorg-2
 
 if [[ ${PV} == 9999* ]]; then
-	EGIT_REPO_URI="https://anongit.freedesktop.org/git/xorg/driver/${PN}"
-	inherit autotools git-r3
-	LIVE_DEPEND=">=x11-misc/util-macros-1.18"
+	SRC_URI=""
 else
-	SRC_URI="mirror://xorg/driver/${P}.tar.bz2"
 	KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
 fi
 
-LICENSE="MIT"
-SLOT="0"
+DESCRIPTION="ATI video driver"
+HOMEPAGE="https://www.x.org/wiki/ati/"
+
 IUSE="+glamor udev"
 
-BDEPEND="
-	virtual/pkgconfig
-"
-RDEPEND="
-	>=x11-libs/libdrm-2.4.78[video_cards_radeon]
+RDEPEND=">=x11-libs/libdrm-2.4.78[video_cards_radeon]
 	>=x11-libs/libpciaccess-0.8.0
-	x11-base/xorg-server:=
 	glamor? ( x11-base/xorg-server[glamor] )
-	udev? ( virtual/libudev:= )
-"
-DEPEND="
-	${LIVE_DEPEND}
-	${RDEPEND}
-	x11-base/xorg-proto
-"
+	udev? ( virtual/libudev:= )"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
 
 pkg_pretend() {
 	if use kernel_linux ; then
@@ -48,21 +35,10 @@ pkg_pretend() {
 	check_extra_config
 }
 
-src_prepare() {
-	default
-	[[ ${PV} == 9999 ]] && eautoreconf
-}
-
 src_configure() {
-	local econfargs=(
-		--disable-selective-werror
+	XORG_CONFIGURE_OPTIONS=(
 		$(use_enable glamor)
 		$(use_enable udev)
 	)
-	econf "${econfargs[@]}"
-}
-
-src_install() {
-	default
-	find "${D}" -name '*.la' -delete || die
+	xorg-2_src_configure
 }