1 files changed, 41 insertions, 0 deletions
diff --git a/dev-ml/cmdliner/cmdliner-1.1.1.ebuild b/dev-ml/cmdliner/cmdliner-1.1.1.ebuild
new file mode 100644
index 000000000000..daf49f5b4986
--- /dev/null
+++ b/dev-ml/cmdliner/cmdliner-1.1.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit findlib
+
+DESCRIPTION="Declarative definition of command line interfaces for OCaml"
+HOMEPAGE="http://erratique.ch/software/cmdliner"
+SRC_URI="http://erratique.ch/software/${PN}/releases/${P}.tbz"
+
+LICENSE="ISC"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="+ocamlopt"
+
+RDEPEND="
+	>=dev-lang/ocaml-4.08.00:=[ocamlopt?]
+	dev-ml/result:=
+	dev-ml/findlib:=
+"
+DEPEND="${RDEPEND}
+	dev-ml/topkg
+	dev-ml/ocamlbuild"
+
+src_compile() {
+	emake build-byte
+	if use ocamlopt ; then
+		emake build-native build-native-dynlink
+	fi
+}
+
+src_install() {
+	# Can't use opam-installer here as it is an opam dep...
+	findlib_src_preinst
+	local nativelibs=""
+	use ocamlopt && nativelibs="$(echo _build/cmdliner.cm{x,xa,xs} _build/cmdliner.a)"
+	ocamlfind install cmdliner pkg/META \
+		_build/cmdliner.mli _build/cmdliner.cm{a,i} ${nativelibs} || die
+	dodoc README.md CHANGES.md
+}