From 5498bd160f1ab0cf37a124c726fead459db05c13 Mon Sep 17 00:00:00 2001
From: Cédric Krier <cedk@gentoo.org>
Date: Sun, 21 Nov 2021 13:09:07 +0100
Subject: www-apps/roundup: version bumps
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/820458
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Cédric Krier <cedk@gentoo.org>
---
 www-apps/roundup/Manifest             |  1 +
 www-apps/roundup/roundup-2.1.0.ebuild | 51 +++++++++++++++++++++++++++++++++++
 2 files changed, 52 insertions(+)
 create mode 100644 www-apps/roundup/roundup-2.1.0.ebuild

diff --git a/www-apps/roundup/Manifest b/www-apps/roundup/Manifest
index 2fa8cc04de4a..f0804e5b918f 100644
--- a/www-apps/roundup/Manifest
+++ b/www-apps/roundup/Manifest
@@ -1 +1,2 @@
 DIST roundup-2.0.0.tar.gz 3495554 BLAKE2B 98b7cbfebe969411282ddf6b4bd7b94ea1efb7b1d929daf44ae5f30dc23c05cb327d0f4653b22a5594f7b198dd16a172c45568a15f8704b187cd4c355455ca9c SHA512 5adb0d96be260e70fe098fd37af27bd0abee38cb8fde4ba2e130d2caac7f64af86a3b0ab09de931a693dca8bfbe15c68444db343ccf718d9d25576d49c6d6cbf
+DIST roundup-2.1.0.tar.gz 3586805 BLAKE2B a5ec6cad38e252e2ffd4d3de4def9b8414ee8758503aa29681d80b36ac62a15700e21e762c6833ce6f795f71a7a1c75c4d9ae30c49c5f038317e5d3fdc58b11d SHA512 ebc047d944f1118b30141b873d91e580d415f1e7c9331875d6efb18cf42c9121163c801b1559d02890165bfd2e5a894c5990b587ce7766b2bf4724745ca9e760
diff --git a/www-apps/roundup/roundup-2.1.0.ebuild b/www-apps/roundup/roundup-2.1.0.ebuild
new file mode 100644
index 000000000000..efc8e54efbc0
--- /dev/null
+++ b/www-apps/roundup/roundup-2.1.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+MY_P=${P/_/}
+
+DESCRIPTION="Issue-tracking system with command-line, web, and e-mail interfaces"
+HOMEPAGE="http://roundup.sourceforge.net https://pypi.org/project/roundup/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="+tz sqlite mysql postgres xapian whoosh ssl jinja pyjwt markdown"
+
+DEPEND=""
+RDEPEND="${DEPEND}
+	tz? ( dev-python/pytz[$PYTHON_USEDEP] )
+	sqlite? ( $(python_gen_impl_dep sqlite) )
+	mysql? ( dev-python/mysqlclient[$PYTHON_USEDEP] )
+	postgres? ( >=dev-python/psycopg-2.8[$PYTHON_USEDEP] )
+	xapian? ( >=dev-libs/xapian-bindings-1.0.0[python,$PYTHON_USEDEP] )
+	whoosh? ( >=dev-python/whoosh-2.5.7[$PYTHON_USEDEP] )
+	ssl? ( dev-python/pyopenssl[$PYTHON_USEDEP] )
+	jinja? ( dev-python/jinja[$PYTHON_USEDEP] )
+	pyjwt? ( dev-python/pyjwt[$PYTHON_USEDEP] )
+	markdown? (
+		|| (
+			dev-python/markdown[$PYTHON_USEDEP]
+			dev-python/markdown2[$PYTHON_USEDEP]
+			dev-python/mistune[$PYTHON_USEDEP]
+			)
+		)"
+
+DOCS="CHANGES.txt doc/*.txt"
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	rm -r "${ED}"/usr/share/doc/${PN} || die
+}
+
+pkg_postinst() {
+	ewarn "See installation.txt for initialisation instructions."
+	ewarn "See upgrading.txt for upgrading instructions."
+}
-- 
cgit v1.2.3-65-gdbad