From 73bdedfdbc98bb5e4fb1837981a7fa0a2dbb1431 Mon Sep 17 00:00:00 2001
From: Andrey Grozin <grozin@gentoo.org>
Date: Fri, 30 Oct 2020 22:36:03 +0700
Subject: app-text/qpdfview: bump to 0.4.18_p1

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Andrey Grozin <grozin@gentoo.org>
---
 app-text/qpdfview/Manifest                  |  1 +
 app-text/qpdfview/qpdfview-0.4.18_p1.ebuild | 86 +++++++++++++++++++++++++++++
 2 files changed, 87 insertions(+)
 create mode 100644 app-text/qpdfview/qpdfview-0.4.18_p1.ebuild

(limited to 'app-text/qpdfview')

diff --git a/app-text/qpdfview/Manifest b/app-text/qpdfview/Manifest
index c4ba32684ed8..170e1a1035e4 100644
--- a/app-text/qpdfview/Manifest
+++ b/app-text/qpdfview/Manifest
@@ -1 +1,2 @@
 DIST qpdfview-0.4.18.tar.gz 786577 BLAKE2B 07ef444ba39435578481e549fcbbd2d97362c6bda3092a17f1daa8b8437febf50cd2f145cd5e80cc1be565c5a658e85a428314a1bcd2a5a38efce0830f1cffba SHA512 38741520b20e3ed7100e52982930abac26e994a69df68c54dfa7180be8b2a4f377b91ba03993bab67b0a505ad79d62164f0f168a6715f4306b635ceba6840d66
+DIST qpdfview-0.4.18_p1.tar.bz2 448818 BLAKE2B 690f93c7f0af376e2b60d69a9802cdb159a97eb66b572a913badcd7ce3b9303d69bf8fbb359b5aa09ad1c63b1b6865e3602c8dc9cdad2506a43273d410a64d89 SHA512 41152596e39e6084e4e46c1aca28dfa4c619bf31068ee3272c6119793da5d99c58868ecf682ed0dc81e740f20193372e2780cf7d7fb917545662c93e6a2a1b4a
diff --git a/app-text/qpdfview/qpdfview-0.4.18_p1.ebuild b/app-text/qpdfview/qpdfview-0.4.18_p1.ebuild
new file mode 100644
index 000000000000..e7a36da831a8
--- /dev/null
+++ b/app-text/qpdfview/qpdfview-0.4.18_p1.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PLOCALES="ast az be bg bs ca cs da de el en_AU en_GB eo es eu fa fi fr gl he hr hu id it ja kk ko ku ky lt lv ms my nb nds oc pl pt pt_BR ro ru sk sr sv th tr ug uk uz vi zh_CN zh_TW"
+inherit l10n qmake-utils xdg
+
+DESCRIPTION="A tabbed document viewer"
+HOMEPAGE="https://launchpad.net/qpdfview"
+# bzr revision 2107
+SRC_URI="https://dev.gentoo.org/~grozin/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="cups +dbus djvu fitz +pdf postscript +sqlite +svg synctex"
+
+REQUIRED_USE="?? ( fitz pdf )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+RDEPEND="
+	cups? ( net-print/cups )
+	djvu? ( app-text/djvu )
+	fitz? ( >=app-text/mupdf-1.7:= )
+	postscript? ( app-text/libspectre )
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5[cups?]
+	dev-qt/qtwidgets:5
+	dbus? ( dev-qt/qtdbus:5 )
+	pdf? ( >=app-text/poppler-0.35[qt5]
+		dev-qt/qtxml:5 )
+	sqlite? ( dev-qt/qtsql:5[sqlite] )
+	svg? ( dev-qt/qtsvg:5 )
+	!svg? ( virtual/freedesktop-icon-theme )
+	synctex? ( app-text/texlive-core )"
+DEPEND="${RDEPEND}"
+
+DOCS=( CHANGES CONTRIBUTORS README TODO )
+
+src_prepare() {
+	default
+
+	local mylrelease="$(qt5_get_bindir)"/lrelease
+	prepare_locale() {
+		"${mylrelease}" "translations/${PN}_${1}.ts" || die "preparing ${1} locale failed"
+	}
+
+	rm_help() {
+		rm -f "help/help_${1}.html" || die "removing ${1} help file failed"
+	}
+
+	l10n_find_plocales_changes translations ${PN}_ .ts
+	l10n_for_each_locale_do prepare_locale
+	l10n_for_each_disabled_locale_do rm_help
+
+	# adapt for prefix
+	sed -i -e "s:/usr:${EPREFIX}/usr:g" qpdfview.pri || die
+}
+
+src_configure() {
+	local myconfig=() i=
+	for i in cups dbus djvu pdf svg synctex; do
+		use ${i} || myconfig+=(without_${i})
+	done
+	use fitz && myconfig+=(with_fitz)
+	use postscript || myconfig+=(without_ps)
+	use sqlite || myconfig+=(without_sql)
+
+	local myqmakeargs=(
+		qpdfview.pro
+		CONFIG+="${myconfig[@]}"
+		PLUGIN_INSTALL_PATH="${EPREFIX}/usr/$(get_libdir)/${PN}"
+	)
+	eqmake5 "${myqmakeargs[@]}"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+	einstalldocs
+}
-- 
cgit v1.2.3-65-gdbad