From 466a8f7b27fdf6e93d17b49d7c415a861ae82573 Mon Sep 17 00:00:00 2001
From: Hans de Graaff <graaff@gentoo.org>
Date: Sat, 21 May 2022 11:45:41 +0200
Subject: dev-util/rbtools: add 3.1

Signed-off-by: Hans de Graaff <graaff@gentoo.org>
---
 dev-util/rbtools/Manifest           |  1 +
 dev-util/rbtools/rbtools-3.1.ebuild | 54 +++++++++++++++++++++++++++++++++++++
 2 files changed, 55 insertions(+)
 create mode 100644 dev-util/rbtools/rbtools-3.1.ebuild

(limited to 'dev-util/rbtools')

diff --git a/dev-util/rbtools/Manifest b/dev-util/rbtools/Manifest
index 552d2591e729..6b20ea1401dd 100644
--- a/dev-util/rbtools/Manifest
+++ b/dev-util/rbtools/Manifest
@@ -1 +1,2 @@
 DIST RBTools-2.0.1.tar.gz 229394 BLAKE2B a3864c5a39854ffd8744cc562fb888aded06b86945b7b08bab1b172e557b80c0183352068722e6d530a7b0c2fae85f24ae1bbef9116538c5c31735ae5c47f313 SHA512 41ef3f6ad030e3551b76cce5358806442ddc78ad14cb3f2f5978d25858b44647fc80a8a98c84edc112d3e121748fa49aeca0ae24287c392d2f8d1d3b72df12ff
+DIST RBTools-3.1.tar.gz 317015 BLAKE2B dccabc93af3a8095f5e166f9e3a31cce52155876cb38675b3dd43b6556024bb9b4ed66291e495ab42b41b09934f136f4eeca7a185fc0fbb2aa2d03e1ef12d656 SHA512 2568aa905dfd119e0b66213e3ae9c8edad5a3337df00228b955006cc85e90c1492e1dc4cccc2695b53f5879103c5d4ee8dba6262112c8781e452dea7633d2c0b
diff --git a/dev-util/rbtools/rbtools-3.1.ebuild b/dev-util/rbtools/rbtools-3.1.ebuild
new file mode 100644
index 000000000000..56041179ce57
--- /dev/null
+++ b/dev-util/rbtools/rbtools-3.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8,9,10} )
+
+inherit distutils-r1
+
+MY_PN="RBTools"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Command line tools for use with Review Board"
+HOMEPAGE="https://www.reviewboard.org/"
+SRC_URI="https://downloads.reviewboard.org/releases/${MY_PN}/$(ver_cut 1-2)/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="
+	>=dev-python/pydiffx-1.0.1-r1[${PYTHON_USEDEP}]
+	>=dev-python/six-1.8.0[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+	dev-python/texttable[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+DOCS=( AUTHORS NEWS README.md )
+
+S=${WORKDIR}/${MY_P}
+
+distutils_enable_tests nose
+
+src_prepare() {
+	default
+
+	# Avoid tests requiring unpackaged test data
+	rm -f rbtools/clients/tests/test_scanning.py || die
+
+	# Avoid repository specific tests to avoid dependencies on them
+	rm -f rbtools/clients/tests/test_{cvs,git,mercurial,svn}.py || die
+
+	# Fix test that appears to expect case-insentive comparison
+	sed -i -e 's/TEST CONTENT/Test content/' rbtools/utils/tests/test_console.py || die
+}
+
+python_test() {
+	distutils_install_for_testing
+	distutils-r1_python_test
+}
-- 
cgit v1.2.3-65-gdbad