From 87cf4e249479edec0cf8750afb5010f12c1c4c59 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sun, 28 Feb 2021 12:50:14 +0100
Subject: net-misc/qtm: Switch to cmake.eclass, don't install compressed man

Closes: https://bugs.gentoo.org/740784
Package-Manager: Portage-3.0.16, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 net-misc/qtm/qtm-1.3.19-r1.ebuild | 60 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 net-misc/qtm/qtm-1.3.19-r1.ebuild

(limited to 'net-misc/qtm/qtm-1.3.19-r1.ebuild')

diff --git a/net-misc/qtm/qtm-1.3.19-r1.ebuild b/net-misc/qtm/qtm-1.3.19-r1.ebuild
new file mode 100644
index 000000000000..27e97c211aa7
--- /dev/null
+++ b/net-misc/qtm/qtm-1.3.19-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Qt blogging client"
+HOMEPAGE="http://qtm.blogistan.co.uk"
+# FIXME find suitable SRC_URI
+SRC_URI="https://bitbucket-archive.softwareheritage.org/static/3c/3c8ca320-701e-47dc-b0ec-28870df5715b/attachments/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="dbus debug"
+RESTRICT="strip"
+
+RDEPEND="
+	dev-lang/perl
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	virtual/perl-Digest-MD5
+	dbus? ( dev-qt/qtdbus:5 )"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+DOCS=( Changelog README )
+
+PATCHES=(
+	"${FILESDIR}/${P}-qt-5.11.patch" # TODO: upstream
+	"${FILESDIR}/${P}-nomancompress.patch" # bug 740784
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	# bug 463810
+	sed -i -e '/Categories/s/Application;//' qtm-desktop.sh || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DQt5=ON
+		-DDONT_USE_PTE=OFF
+		-DINSTALL_MARKDOWN=ON
+		-DNO_SSL=OFF
+		-DUSE_DBUS=$(usex dbus)
+		-DDONT_USE_DBUS=$(usex !dbus)
+		-DQDEBUG=$(usex debug)
+	)
+	cmake_src_configure
+}
-- 
cgit v1.2.3-65-gdbad