From 257fa9c839ae2ba2a63a4daa683a4b25cb70bcdd Mon Sep 17 00:00:00 2001
From: François Bissey <frp.bissey@gmail.com>
Date: Tue, 6 Jun 2023 09:43:46 +1200
Subject: sci-libs/umfpack: add 6.1.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: François Bissey <frp.bissey@gmail.com>
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>
---
 sci-libs/umfpack/umfpack-6.1.0.ebuild | 70 +++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 sci-libs/umfpack/umfpack-6.1.0.ebuild

(limited to 'sci-libs/umfpack/umfpack-6.1.0.ebuild')

diff --git a/sci-libs/umfpack/umfpack-6.1.0.ebuild b/sci-libs/umfpack/umfpack-6.1.0.ebuild
new file mode 100644
index 000000000000..c83986c4ee4a
--- /dev/null
+++ b/sci-libs/umfpack/umfpack-6.1.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib toolchain-funcs
+
+Sparse_PV="7.0.0"
+Sparse_P="SuiteSparse-${Sparse_PV}"
+DESCRIPTION="Unsymmetric multifrontal sparse LU factorization library"
+HOMEPAGE="https://people.engr.tamu.edu/davis/suitesparse.html"
+SRC_URI="https://github.com/DrTimothyAldenDavis/SuiteSparse/archive/refs/tags/v${Sparse_PV}.tar.gz -> ${Sparse_P}.gh.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0/6"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc openmp test"
+RESTRICT="!test? ( test )"
+
+DEPEND=">=sci-libs/suitesparseconfig-${Sparse_PV}
+	>=sci-libs/amd-3.0.3
+	>=sci-libs/cholmod-4.0.3[openmp=]
+	virtual/blas"
+RDEPEND="${DEPEND}"
+BDEPEND="doc? ( virtual/latex-base )"
+
+S="${WORKDIR}/${Sparse_P}/${PN^^}"
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+multilib_src_configure() {
+	# Fortran is only used to compile additional demo programs that can be tested.
+	local mycmakeargs=(
+		-DNSTATIC=ON
+		-DNOPENMP=$(usex openmp OFF ON)
+		-DNFORTRAN=ON
+		-DDEMO=$(usex test)
+	)
+	cmake_src_configure
+}
+
+multilib_src_test() {
+	# Run demo files
+	local demofiles=(
+		umfpack_di_demo
+		umfpack_dl_demo
+		umfpack_zi_demo
+		umfpack_zl_demo
+	)
+	for i in ${demofiles}; do
+		./"${i}" > "${i}.out"
+		diff --strip-trailing-cr "${S}/Demo/${i}.out" "${i}.out" || die "failed testing ${i}"
+	done
+}
+multilib_src_install() {
+	if use doc; then
+		pushd "${S}/Doc"
+		rm -rf *.pdf
+		emake
+		popd
+		DOCS="${S}/Doc/*.pdf"
+	fi
+	cmake_src_install
+}
-- 
cgit v1.2.3-65-gdbad