blob: 66c9951b7db2a16b296fd01217662552c8a9effd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1
DESCRIPTION="Tools for generating printable PDF documents from any data source"
HOMEPAGE="
https://www.reportlab.com/
https://pypi.org/project/reportlab/"
SRC_URI="
mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz
https://www.reportlab.com/ftp/fonts/pfbfer-20070710.zip"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux"
DEPEND="
media-libs/freetype
media-libs/libart_lgpl
sys-libs/zlib:="
RDEPEND="
${DEPEND}
dev-python/pillow[tiff,truetype,jpeg(+),${PYTHON_USEDEP}]"
BDEPEND="
app-arch/unzip"
distutils_enable_sphinx docs/source
distutils_enable_tests unittest
PATCHES=(
# bug 738312, remove -L/usr/lib from link line
"${FILESDIR}"/${PN}-3.5.48-usr-lib-LLD.patch
)
src_unpack() {
unpack ${P}.tar.gz
cd ${P}/src/reportlab/fonts || die
unpack pfbfer-20070710.zip
}
src_configure() {
DISTUTILS_ARGS=(
--no-download-t1-files
--use-system-libart
)
}
python_test() {
pushd tests >/dev/null || die
"${EPYTHON}" runAll.py -v || die "Testing failed with ${EPYTHON}"
popd >/dev/null || die
}
|
GitWeb
