blob: fd799d2a1495714c0b8bc3e21ca575af9fb26c63 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools systemd
DESCRIPTION="Another (RFC1413 compliant) ident daemon"
HOMEPAGE="https://oidentd.janikrabe.com/"
SRC_URI="https://files.janikrabe.com/pub/${PN}/releases/${PV}/${P}.tar.xz"
LICENSE="BSD-2 GPL-2 LGPL-2+ MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ~mips ppc ppc64 ~s390 ~sparc x86"
IUSE="debug ipv6 masquerade selinux"
DEPEND="masquerade? ( net-libs/libnetfilter_conntrack )"
RDEPEND="
acct-user/oidentd
acct-group/oidentd
selinux? ( sec-policy/selinux-oident )
${DEPEND}"
PATCHES=( "${FILESDIR}/${P}-respect-ar.patch" )
src_prepare() {
sed -i '/ExecStart/ s|$| -u oidentd -g oidentd|' contrib/systemd/*.service || die
default
eautoreconf
}
src_configure() {
local myconf=(
$(use_enable debug)
$(use_enable ipv6)
$(use_enable masquerade libnfct)
$(use_enable masquerade nat)
--enable-xdgbdir
)
econf "${myconf[@]}"
}
src_install() {
default
newinitd "${FILESDIR}"/${PN}-2.0.7-init ${PN}
newconfd "${FILESDIR}"/${PN}-2.2.2-confd ${PN}
systemd_dounit contrib/systemd/${PN}@.service
systemd_dounit contrib/systemd/${PN}.socket
systemd_dounit contrib/systemd/${PN}.service
}
|
GitWeb
