Version bump.

Package-Manager: portage-2.2_rc77/cvs/Linux x86_64

4 files changed, 216 insertions, 2 deletions

diff --git a/net-p2p/vuze-coreplugins/ChangeLog b/net-p2p/vuze-coreplugins/ChangeLog
index f6ce2e84248d..b06bfc97a081 100644
--- a/net-p2p/vuze-coreplugins/ChangeLog
+++ b/net-p2p/vuze-coreplugins/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-p2p/vuze-coreplugins
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/vuze-coreplugins/ChangeLog,v 1.30 2010/08/26 10:20:38 caster Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/vuze-coreplugins/ChangeLog,v 1.31 2010/09/09 21:46:18 caster Exp $
+
+*vuze-coreplugins-4.5.0.4 (09 Sep 2010)
+
+  09 Sep 2010; Vlastimil Babka <caster@gentoo.org>
+  +vuze-coreplugins-4.5.0.4.ebuild:
+  Version bump.
 
 *vuze-coreplugins-4.5.0.2 (26 Aug 2010)
 
diff --git a/net-p2p/vuze-coreplugins/vuze-coreplugins-4.5.0.4.ebuild b/net-p2p/vuze-coreplugins/vuze-coreplugins-4.5.0.4.ebuild
new file mode 100644
index 000000000000..27d52ba1e2bc
--- /dev/null
+++ b/net-p2p/vuze-coreplugins/vuze-coreplugins-4.5.0.4.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/vuze-coreplugins/vuze-coreplugins-4.5.0.4.ebuild,v 1.1 2010/09/09 21:46:18 caster Exp $
+
+# eventually this should be built from source...
+
+EAPI=2
+
+inherit eutils
+
+PLUGINS_N=azplugins
+RATING_N=azrating
+UPDATER_N=azupdater
+UPNPAV_N=azupnpav
+PLUGINS_V=2.1.6
+RATING_V=1.3.1
+UPDATER_V=1.8.16
+UPNPAV_V=0.2.30
+PLUGINS_DIST=${PLUGINS_N}_${PLUGINS_V}.jar
+RATING_DIST=${RATING_N}_${RATING_V}.jar
+UPDATER_DIST=${UPDATER_N}_${UPDATER_V}.zip
+UPNPAV_DIST=${UPNPAV_N}_${UPNPAV_V}.zip
+
+ALLPLUGINS_URL="http://azureus.sourceforge.net/plugins"
+
+DESCRIPTION="Core plugins for Vuze that are included in upstream distribution"
+HOMEPAGE="http://www.vuze.com/"
+SRC_URI="
+	${ALLPLUGINS_URL}/${PLUGINS_DIST}
+	${ALLPLUGINS_URL}/${RATING_DIST}
+	${ALLPLUGINS_URL}/${UPDATER_DIST}
+	${ALLPLUGINS_URL}/${UPNPAV_DIST}"
+LICENSE="GPL-2 BSD"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="~net-p2p/vuze-${PV}"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S="${WORKDIR}"
+
+src_unpack() {
+	mkdir -p plugins/{${PLUGINS_N},${RATING_N},${UPDATER_N},${UPNPAV_N}} || die
+	cp "${DISTDIR}/${PLUGINS_DIST}" plugins/${PLUGINS_N} || die
+	cp "${DISTDIR}/${RATING_DIST}" plugins/${RATING_N} || die
+	cd "${WORKDIR}/plugins/${UPDATER_N}" && unpack ${UPDATER_DIST} || die
+	cd "${WORKDIR}/plugins/${UPNPAV_N}" && unpack ${UPNPAV_DIST} || die
+}
+
+src_compile() { :; }
+
+src_install() {
+	insinto /usr/share/vuze/
+	doins -r "${WORKDIR}/plugins"
+}
+
+pkg_postinst() {
+	elog "Since version 4.0.0.2, plugins that are normally bundled by upstream"
+	elog "(and auto-installed in each user's ~/.azureus if not bundled)"
+	elog "are now installed into shared plugin directory by the ebuild."
+	elog "Vuze may warn that shared plugin dir is not writable, that's fine."
+	elog "Users are recommended to delete the following plugin copies:"
+	elog "~/.azureus/plugins/{${PLUGINS_N},${RATING_N},${UPDATER_N},${UPNPAV_N}}"
+}
diff --git a/net-p2p/vuze/ChangeLog b/net-p2p/vuze/ChangeLog
index d12166a12b80..96696ab52d53 100644
--- a/net-p2p/vuze/ChangeLog
+++ b/net-p2p/vuze/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-p2p/vuze
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/vuze/ChangeLog,v 1.40 2010/08/26 10:19:46 caster Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/vuze/ChangeLog,v 1.41 2010/09/09 21:46:45 caster Exp $
+
+*vuze-4.5.0.4 (09 Sep 2010)
+
+  09 Sep 2010; Vlastimil Babka <caster@gentoo.org> +vuze-4.5.0.4.ebuild:
+  Version bump.
 
 *vuze-4.5.0.2 (26 Aug 2010)
 
diff --git a/net-p2p/vuze/vuze-4.5.0.4.ebuild b/net-p2p/vuze/vuze-4.5.0.4.ebuild
new file mode 100644
index 000000000000..97b9578d4628
--- /dev/null
+++ b/net-p2p/vuze/vuze-4.5.0.4.ebuild
@@ -0,0 +1,136 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/vuze/vuze-4.5.0.4.ebuild,v 1.1 2010/09/09 21:46:45 caster Exp $
+
+EAPI=2
+
+JAVA_PKG_IUSE="source"
+
+inherit eutils fdo-mime java-pkg-2 java-ant-2 versionator
+
+MY_PV=$(replace_all_version_separators "")
+
+PATCHSET_VER="4.5.0.2"
+PATCHSET_DIR="${PN}-${PATCHSET_VER}-gentoo-patches"
+PATCHSET="${PATCHSET_DIR}.tar.bz2"
+SRC_TARBALL="Vuze_${MY_PV}_source.zip"
+
+DESCRIPTION="BitTorrent client in Java, formerly called Azureus"
+HOMEPAGE="http://www.vuze.com/"
+SRC_URI="mirror://sourceforge/azureus/${PN}/Vuze_${MY_PV}/${SRC_TARBALL}
+	mirror://gentoo/${PATCHSET}"
+LICENSE="GPL-2 BSD"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE=""
+
+# bundles parts of commons-lang, but modified
+# bundles parts of http://www.programmers-friend.org/
+RDEPEND="
+	dev-java/json-simple:0
+	dev-java/bcprov:1.3
+	>=dev-java/commons-cli-1.0:1
+	>=dev-java/log4j-1.2.8:0
+	dev-java/swt:3.6[cairo,xulrunner]
+	!net-p2p/azureus-bin
+	>=virtual/jre-1.5"
+
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-util/desktop-file-utils
+	>=virtual/jdk-1.5"
+
+PDEPEND="~net-p2p/vuze-coreplugins-${PV}"
+
+src_unpack() {
+	unpack ${PATCHSET}
+	mkdir "${S}" && cd "${S}" || die
+	unpack ${SRC_TARBALL}
+}
+
+java_prepare() {
+	# build.xml disappeared from 4.4.0.0 although it was there in 4.3.1.4
+	# hopefully that's just a packaging mistake
+	[[ -f build.xml ]] && die "upstream has build.xml again, don't overwrite"
+	cp "${FILESDIR}/build.xml" . || die "failed to copy build.xml"
+
+	EPATCH_FORCE="yes" EPATCH_SUFFIX="patch" epatch "${WORKDIR}/${PATCHSET_DIR}/"
+
+	### Removes OS X files and entries.
+	rm -rv "org/gudy/azureus2/platform/macosx" \
+		   "org/gudy/azureus2/ui/swt/osx" || die
+
+	### Removes Windows files.
+	rm -v ./org/gudy/azureus2/ui/swt/win32/Win32UIEnhancer.java || die
+
+	### Removes test files.
+	rm -rv org/gudy/azureus2/ui/console/multiuser/TestUserManager.java || die
+
+	### Removes bouncycastle (we use our own bcprov).
+	rm -rv "org/bouncycastle" || die
+
+	### Removes bundled json
+	rm -rv "org/json" || die
+
+	### The Tree2 file does not compile against Linux SWT and is used only on Windows.
+	### It's runtime-conditional use is thus patched out in the patchset.
+	rm -rf "org/eclipse" || die
+
+	mkdir -p build/libs || die
+}
+
+JAVA_ANT_REWRITE_CLASSPATH="true"
+EANT_GENTOO_CLASSPATH="swt-3.6,bcprov-1.3,json-simple,log4j,commons-cli-1"
+
+src_compile() {
+	local mem
+	use amd64 && mem="256"
+	use x86   && mem="192"
+	use ppc   && mem="192"
+	use ppc64 && mem="256"
+	export ANT_OPTS="-Xmx${mem}m"
+	java-pkg-2_src_compile
+
+	# bug #302058 - build.xml excludes .txt but upstream jar has it...
+	jar uf dist/Azureus2.jar ChangeLog.txt || die
+}
+
+src_install() {
+	java-pkg_dojar dist/Azureus2.jar
+	dodoc ChangeLog.txt || die
+
+	java-pkg_dolauncher "${PN}" \
+		--main org.gudy.azureus2.ui.common.Main -pre "${FILESDIR}/${PN}-4.1.0.0-pre" \
+		--java_args '-Dazureus.install.path=/usr/share/vuze/ ${JAVA_OPTIONS}' \
+		--pkg_args '--ui=${UI}'
+	dosym vuze /usr/bin/azureus
+
+	# https://bugs.gentoo.org/show_bug.cgi?id=204132
+	java-pkg_register-environment-variable MOZ_PLUGIN_PATH /usr/lib/nsbrowser/plugins
+
+	newicon "${S}"/org/gudy/azureus2/ui/icons/a32.png vuze.png
+	domenu "${FILESDIR}/${PN}.desktop"
+
+	use source && java-pkg_dosrc "${S}"/{com,edu,org}
+}
+
+pkg_postinst() {
+	ewarn "Running Vuze as root is not supported and may result in untracked"
+	ewarn "updates to shared components and then collisions on updates via ebuilds"
+
+	elog "Vuze has been formerly called Azureus and many references to the old name remain."
+	elog
+	elog "After running Vuze for the first time, configuration"
+	elog "options will be placed in '~/.azureus/gentoo.config'."
+	elog "If you need to change some startup options, you should"
+	elog "modify this file, rather than the startup script."
+	elog "Using this config file you can start the console UI."
+	elog
+
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}