From 108938198a3de1e8455c1523d6330ec9c9f0bc03 Mon Sep 17 00:00:00 2001
From: Michael Palimaka <kensington@gentoo.org>
Date: Thu, 7 Feb 2013 12:12:33 +0000
Subject: Migrate to EAPI 5 and add a subslot dependency for dev-libs/icu wrt
 bug #455900.

Package-Manager: portage-2.1.11.50/cvs/Linux x86_64
Manifest-Sign-Key: 0x675D0D2C
---
 net-nntp/tin/tin-2.0.1-r1.ebuild | 95 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 95 insertions(+)
 create mode 100644 net-nntp/tin/tin-2.0.1-r1.ebuild

(limited to 'net-nntp/tin/tin-2.0.1-r1.ebuild')

diff --git a/net-nntp/tin/tin-2.0.1-r1.ebuild b/net-nntp/tin/tin-2.0.1-r1.ebuild
new file mode 100644
index 000000000000..5b4cd0890a22
--- /dev/null
+++ b/net-nntp/tin/tin-2.0.1-r1.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-nntp/tin/tin-2.0.1-r1.ebuild,v 1.1 2013/02/07 12:12:14 kensington Exp $
+
+EAPI=5
+inherit autotools eutils toolchain-funcs versionator
+
+DESCRIPTION="A threaded NNTP and spool based UseNet newsreader"
+HOMEPAGE="http://www.tin.org/"
+SRC_URI="ftp://ftp.tin.org/pub/news/clients/tin/v$(get_version_component_range 1-2)/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="cancel-locks debug doc +etiquette evil forgery gpg idn ipv6 mime nls sasl socks5 spell unicode"
+
+RDEPEND="
+	dev-libs/libpcre
+	dev-libs/uulib
+	gpg? ( app-crypt/gnupg )
+	idn? ( net-dns/libidn )
+	mime? ( net-mail/metamail )
+	net-misc/urlview
+	nls? ( sys-devel/gettext )
+	sasl? ( virtual/gsasl )
+	socks5? ( net-proxy/dante )
+	sys-libs/ncurses[unicode?]
+	unicode? ( dev-libs/icu:= )
+"
+
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Do not strip
+	sed -i src/Makefile.in -e '388s|-s ||g' || die "sed src/Makefile.in failed"
+	sed -i configure.in -e '/CFLAGS/s|-g||g' || die
+	eautoreconf
+}
+
+src_configure() {
+	if use evil || use cancel-locks; then
+		sed -i -e"s/# -DEVIL_INSIDE/-DEVIL_INSIDE/" src/Makefile.in
+	fi
+
+	if use forgery
+	then
+		sed -i -e"s/^CPPFLAGS.*/& -DFORGERY/" src/Makefile.in
+	fi
+
+	local screen="ncurses"
+	use unicode && screen="ncursesw"
+
+	use etiquette || myconf="${myconf} --disable-etiquette"
+
+	tc-export AR CC RANLIB
+
+	econf \
+		$(use_enable cancel-locks) \
+		$(use_enable debug) \
+		$(use_enable gpg pgp-gpg) \
+		$(use_enable ipv6) \
+		$(use_enable nls) \
+		$(use_with mime metamail /usr) \
+		$(use_with socks5 socks) $(use_with socks5) \
+		$(use_with spell ispell /usr) \
+		--disable-mime-strict-charset \
+		--enable-echo \
+		--enable-nntp-only \
+		--enable-prototypes \
+		--with-coffee  \
+		--with-nntp-default-server="${TIN_DEFAULT_SERVER:-${NNTPSERVER:-news.gmane.org}}" \
+		--with-pcre=/usr \
+		--with-screen=${screen} \
+		${myconf}
+}
+
+src_compile() {
+	emake build
+}
+
+src_install() {
+	default
+
+	# File collision?
+	rm -f "${ED}"/usr/share/man/man5/{mbox,mmdf}.5
+
+	dodoc doc/{CHANGES{,.old},CREDITS,TODO,WHATSNEW}
+	use doc && dodoc doc/{*.sample,*.txt}
+
+	insinto /etc/tin
+	doins doc/tin.defaults
+}
-- 
cgit v1.2.3-65-gdbad