games-util/hearse/hearse-1.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

# Copyright 1999-2003 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-util/hearse/hearse-1.4.ebuild,v 1.1 2003/11/25 11:05:46 mr_bones_ Exp $

inherit games

DESCRIPTION="exchange Nethack bones files with other players"
HOMEPAGE="http://www.argon.org/~roderick/hearse/"
SRC_URI="http://www.argon.org/~roderick/hearse/dist/${P}.tar.gz"

KEYWORDS="~x86"
LICENSE="GPL-2"
SLOT="0"
IUSE=""

DEPEND=">=dev-lang/perl-5.8.0
	>=games-roguelike/nethack-3.4.1
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${A}
	cd ${S}

	# patch because Gentoo's nethack ebuild uses bz2 and not gz for bones
	sed -i \
		-e "s:gzip :bzip2 :" \
		-e "s:.gz:.bz2:" hearse || \
			die "sed hearse failed"
	sed -i \
		-e 's:gzip :bzip2 :' \
		-e "s:gz|z|Z:bz2:" bones-info || \
			die "sed bones-info failed"
}
src_compile() {
	perl Makefile.PL || die "perl failed"
	emake            || die "emake failed"
}

src_install() {
	dogamesbin hearse bones-info        || die "dogamesbin failed"
	doman blib/man1/*.1                 || die "doman failed"
	dodoc Notes README debian/changelog || die "dodoc failed"
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	einfo "As root, run \"${GAMES_BINDIR}/hearse --user-email your@address.com\" to activate."
	einfo "Add the following to /etc/crontab to automatically exchange bones:"
	einfo "   0 3 * * * root perl -we 'sleep rand 3600'; ${GAMES_BINDIR}/hearse --quiet"
}