dev-python/tox: Bump to 4.2.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index bd8cdc615917..0e1293c13f6f 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -3,3 +3,4 @@ DIST tox-3.28.0.gh.tar.gz 309472 BLAKE2B 9896411426f6aebb3efa468c01696ecc5f17ec3
 DIST tox-4.1.2.gh.tar.gz 286306 BLAKE2B 67e52bf01c383e255b22c5c71eecf01d4a041cf4c4399df60451c74acd79bbd1b30f787bcf4f10896804ca1b0cc8b02f6ff4d5e0b7e7ac64284da33f09c95bc9 SHA512 7ff44624c26d609c33dce2cec5bd177caf70b8628f64c48f1fae5130001c508b82079ea4f2487cf8d10b371d0b95cc998c21c47a5080e964db40a3ebafe01a93
 DIST tox-4.1.3.gh.tar.gz 286917 BLAKE2B 0dc7979be947087a126325947b73bbf832c714d2a5543b72eb7d1eaeff4fffb440c07b2d6cd76842d8a9afb7ea2187fd5e9c2c6ae5eb6001b6aa925a08de3ef4 SHA512 d7502180b363f1f99037e30299cc77ba35259812463c44d82bd4953a3b15e19f44cc33184c23c2f80868cb8b9bdb78efd702482af901b69a2e06984ffd105f1b
 DIST tox-4.2.1.gh.tar.gz 289672 BLAKE2B d5ca6a793d1058a48c7a3fb42f6b37e4d803e1f60ee9bcc80fedeb3c5e07d467967c1d08bbfe7a8503ac9a06b5b822a2675fd2757021cdc6325ffb9f8a2e7fc9 SHA512 fd717cdec6413ba6f0949d82f2ef6d144d619857c624116e9394bc9c46c55b8c95e6c4e58afec17f50b656587cf2a2b6283c06050a9d2e87a4fcd96b632dfb14
+DIST tox-4.2.3.gh.tar.gz 290003 BLAKE2B 2ccd1b511114e8a06312922460b39e37de4ac347551ef3595e17d7d972b0049702e8113f1df2470eed90e21a6020dcbb5c88ad976daecaa0259de36233917c4e SHA512 4f9493a32bcc3c1014c89f2a658babc5a6bd12b96a6a5e9f657b6cd750cb787a296ebb58e4d77cd9239cdaaa687eed870d3b7eec76ee91a870a4ed731895b24e
diff --git a/dev-python/tox/tox-4.2.3.ebuild b/dev-python/tox/tox-4.2.3.ebuild
new file mode 100644
index 000000000000..7acdcbeea4a2
--- /dev/null
+++ b/dev-python/tox/tox-4.2.3.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+SRC_URI="
+	https://github.com/tox-dev/tox/archive/${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~riscv"
+
+RDEPEND="
+	>=dev-python/cachetools-5.2[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.8.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.2.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	>=dev-python/virtualenv-20.17.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.4[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	# the minimal bounds in tox are entirely meaningless and new packaging
+	# breaks setuptools
+	sed -i -e '/packaging/s:>=22::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	epytest
+}