dev-python/django: Bump to 3.2.24

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 111 insertions, 0 deletions

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 23d5e87c30e8..4ccb5d665e59 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -1,5 +1,7 @@
 DIST Django-3.2.23.checksum.txt 2563 BLAKE2B 59bc9c0946de84be99057be9f044e59f7fd87d1a4043041033916fbc0052a8d4f8d2b02bfe591374fba7bf54c6d2ea1ee8f4739bdbd49a369312e8792fe2a1f7 SHA512 356379166f9375175b896cf07ff2debbbed3cff859597cf8600a3e14e0660c15914f561c54bba2bdb38742c5ec4f9f1bd412baef5f6271548a1f76485f61eaea
 DIST Django-3.2.23.tar.gz 9834665 BLAKE2B 365ab5101e610ed1d0ed504cd538cc90a8d5d0730fcb43dab12b8f0ce1d1f2a6d42e4e36eccaf84d242e4fc9d9c75fefc5062ac1e8d077cb784eea741df716ee SHA512 a252e4000c932a906eef22d0cb91a9dcb802eb65bbe0fc0eb881216b6801dbef5123b21f51f3208def155852c20e8d7e9adc8339b6386fc49bbc00f7c4d2d4ba
+DIST Django-3.2.24.checksum.txt 2583 BLAKE2B 87fa39627676d4ce75058df6dfc286eae160401b617a8c6e0e249cb4f2c608e00e9bd23ae8fd46fe405dc7fa94a2cd684dc943298dd4af430e370bf77ef0a386 SHA512 1475ec74eb389db2bb47cc5fb00080907a59534cc9f48ac9e5e3b275cbf8de3ada43377fe4e1ab22dfa30a43069e04db2f7a1a441cb60119bb5f835fd3a5ccb8
+DIST Django-3.2.24.tar.gz 9833004 BLAKE2B d3809547f95aa266c1287cfa6d1fee32561456dc55763124138ed9b3afe2071b2bd45a737814210cc47c3d0033326ddebdc62f7c2902c6719d95a6ff895e5c1b SHA512 840b4c87e159d9714ac816fffb09faba76d3b130a76caffff68b7edd59e9488832ccd8c5ffaa8f0d066f0faa029f6ef2395f6a8e9351eaa1bcbd316d50965fc8
 DIST Django-4.1.13.checksum.txt 2563 BLAKE2B 2569a6c7854f4941f88ae3b7556e4e75d7633b333ef9723c137f266ae1c0b89c20911b89097bfbb2e0d1360349b4eda6d4b0778ac358665327a9f23e8b58ad21 SHA512 e2cc70520c4008322e7ee68bd2a32abeb58f6cac52198498ec7936b593e39ce924a4bd43df69a4f9edd625f1f5142be4b8043d33514237febecc302c2389e2c3
 DIST Django-4.1.13.tar.gz 10515104 BLAKE2B d0f53d53a7c37acf446bbd8806c15a3e31f6acb51f3e8f8616c690e3ee907bce9089d03c0514c3cb25e905a5edc4aec433584f551e0b016c94e11106b65873fe SHA512 405453aeb8d5462f1eb5b3171dd441e6699bad98fd34e31efda2af5f249f82d17a880ed8d97177cf56bcc27acf763081375c0043e9e6f0d60fa32148981a2562
 DIST Django-4.2.10.checksum.txt 2583 BLAKE2B 5529d8d83fb2ed7ca644ab929809f13ac59225f23b9590f3ab97d4926da7e10d6d3f47e2638c845e7b2cff3c1dd2a0ed50105d23bf3eff4c689811e1785a0661 SHA512 64bec1d2f31627d9347b93b1d947b80eee70257bc967393dfe8af5b56d845ec21ffdd2aba11106a5b4fe13d55a51949b8b156b341eca4327082fd21ee0db35b4
diff --git a/dev-python/django/django-3.2.24.ebuild b/dev-python/django/django-3.2.24.ebuild
new file mode 100644
index 000000000000..6fd28d4ce937
--- /dev/null
+++ b/dev-python/django/django-3.2.24.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1-bashcomp.patch
+	"${FILESDIR}"/django-3.2.19-py311.patch
+	# needed for Python 3.11
+	"${FILESDIR}"/django-3.2.20-urlsplit.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_prepare_all() {
+	# Fails because of warnings
+	sed -i 's/test_dumpdata_proxy_with_concrete/_&/' tests/fixtures/tests.py || die
+	# TODO: this suddenly started failing
+	sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+}