dev-util/dwarves: Fix python shebang and add more supported versions

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Matthias Schwarzott <zzam@gentoo.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-util/dwarves/dwarves-1.19-r1.ebuild b/dev-util/dwarves/dwarves-1.19-r1.ebuild
new file mode 100644
index 000000000000..f37545621fa9
--- /dev/null
+++ b/dev-util/dwarves/dwarves-1.19-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+inherit multilib cmake python-single-r1
+
+DESCRIPTION="pahole (Poke-a-Hole) and other DWARF2 utilities"
+HOMEPAGE="https://git.kernel.org/cgit/devel/pahole/pahole.git/"
+
+LICENSE="GPL-2" # only
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="debug"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-libs/elfutils-0.178
+	sys-libs/zlib"
+DEPEND="${RDEPEND}"
+
+if [[ ${PV//_p} == ${PV} ]]; then
+	SRC_URI="http://fedorapeople.org/~acme/dwarves/${P}.tar.xz"
+else
+	SRC_URI="https://dev.gentoo.org/~zzam/${PN}/${P}.tar.xz"
+fi
+
+DOCS=( README README.ctracer NEWS )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.10-python-import.patch
+)
+
+src_prepare() {
+	cmake_src_prepare
+	python_fix_shebang ostra/ostra-cg ostra/python/ostra.py
+}
+
+src_configure() {
+	local mycmakeargs=( "-D__LIB=$(get_libdir)" )
+	cmake_src_configure
+}
+
+src_test() { :; }
+
+src_install() {
+	cmake_src_install
+}