gui-wm/gamescope: Version bump to 3.11.52_beta1

This version introduces HDR support but requires AMDGPU and a custom kernel.

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

4 files changed, 79 insertions, 1 deletions

diff --git a/gui-wm/gamescope/Manifest b/gui-wm/gamescope/Manifest
index 60bdaefe23ee..b655ded3798c 100644
--- a/gui-wm/gamescope/Manifest
+++ b/gui-wm/gamescope/Manifest
@@ -1 +1,2 @@
 DIST gamescope-3.11.51.tar.gz 209920 BLAKE2B fdccd6659e33a9ae43eaabc5d41cfa6d0a92bda1a283e23f101296713f5094093b7b41135de44abd65ff17c66d70b27baf50685dcd2a47084022fb611e150a5b SHA512 a4ddd96a4fdacd62eee800f6fb331d08fca32c2798d64148529181a0ee8d8af57d5d67bfa28bff8e9cf62047a7572c43b36e2968660ea2984b8e21fa812baf9e
+DIST gamescope-3.11.52_beta1.tar.gz 256753 BLAKE2B b25dc6609ab4f2639c7dfa1d972c41697632cc2fc7afc8bb6eeaa6271bf16fe19f9a4f553395eefbdc92f2d896c2f9e7489bdb664ea679a8b514ac5c8a50b60c SHA512 7fb8e2d45e6eb66bb8dbdac9aa39e4492d27b9b7b6175314877082c83cdf8891eb1bd00d86b9109e392b4c877919956feaa420c0d71e59e34e224f7223050ada
diff --git a/gui-wm/gamescope/gamescope-3.11.51.ebuild b/gui-wm/gamescope/gamescope-3.11.51.ebuild
index a8464a5a2e68..b8dbd943a190 100644
--- a/gui-wm/gamescope/gamescope-3.11.51.ebuild
+++ b/gui-wm/gamescope/gamescope-3.11.51.ebuild
@@ -42,7 +42,7 @@ DEPEND="
 	${RDEPEND}
 	dev-libs/stb
 	dev-util/vulkan-headers
-	media-libs/vkroots
+	~media-libs/vkroots-0_p20221205
 "
 BDEPEND="
 	dev-util/glslang
diff --git a/gui-wm/gamescope/gamescope-3.11.52_beta1.ebuild b/gui-wm/gamescope/gamescope-3.11.52_beta1.ebuild
new file mode 100644
index 000000000000..83d9cba188f7
--- /dev/null
+++ b/gui-wm/gamescope/gamescope-3.11.52_beta1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit fcaps meson
+
+MY_PV=$(ver_rs 3 -)
+MY_PV="${MY_PV//_/-}"
+DESCRIPTION="Efficient micro-compositor for running games"
+HOMEPAGE="https://github.com/Plagman/gamescope"
+SRC_URI="https://github.com/Plagman/${PN}/archive/refs/tags/${MY_PV}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="pipewire +wsi-layer"
+
+RDEPEND="
+	=dev-libs/libliftoff-0.3*
+	>=dev-libs/wayland-1.21
+	>=dev-libs/wayland-protocols-1.17
+	=gui-libs/wlroots-0.16*[X]
+	media-libs/libdisplay-info
+	media-libs/libsdl2[video,vulkan]
+	media-libs/vulkan-loader
+	sys-apps/hwdata
+	sys-libs/libcap
+	>=x11-libs/libdrm-2.4.109
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libXrender
+	x11-libs/libXres
+	x11-libs/libXtst
+	x11-libs/libXxf86vm
+	pipewire? ( >=media-video/pipewire-0.3:= )
+	wsi-layer? ( x11-libs/libxcb )
+"
+DEPEND="
+	${RDEPEND}
+	dev-libs/stb
+	dev-util/vulkan-headers
+	wsi-layer? ( >=media-libs/vkroots-0_p20230103 )
+"
+BDEPEND="
+	dev-util/glslang
+	dev-util/wayland-scanner
+"
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+FILECAPS=(
+	cap_sys_nice usr/bin/${PN}
+)
+
+src_prepare() {
+	default
+
+	# Normally wraps stb with Meson. Upstream does not ship a pkg-config file so
+	# we don't install one. Work around this using symlinks.
+	mkdir subprojects/stb || die
+	ln -sn "${ESYSROOT}"/usr/include/stb/* "${S}"/subprojects/packagefiles/stb/* subprojects/stb/ || die
+}
+
+src_configure() {
+	local emesonargs=(
+		--force-fallback-for=
+		-Denable_openvr_support=false
+		$(meson_feature pipewire)
+		$(meson_use wsi-layer enable_gamescope_wsi_layer)
+	)
+	meson_src_configure
+}
diff --git a/gui-wm/gamescope/metadata.xml b/gui-wm/gamescope/metadata.xml
index 97b39dd3f361..f2337907378b 100644
--- a/gui-wm/gamescope/metadata.xml
+++ b/gui-wm/gamescope/metadata.xml
@@ -10,5 +10,6 @@
 	</upstream>
 	<use>
 		<flag name="pipewire">Enable screen capture via PipeWire</flag>
+		<flag name="wsi-layer">Enable the WSI layer (required for HDR)</flag>
 	</use>
 </pkgmetadata>