net-libs/gnome-online-accounts: Version bump to 3.40.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 81 insertions, 0 deletions

diff --git a/net-libs/gnome-online-accounts/Manifest b/net-libs/gnome-online-accounts/Manifest
index a38bee99da60..0f2b093e8a67 100644
--- a/net-libs/gnome-online-accounts/Manifest
+++ b/net-libs/gnome-online-accounts/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-online-accounts-3.36.0.tar.xz 860472 BLAKE2B 921f2f5ed9ac3db07046507723d814fc41579aee76cd2437673cdc3612db1077627ab47586e719b56a5bce25afe75b8028477f69745791eeb774c82bf854863d SHA512 2d04ea016c1bace9a2cb6ef7a6539c7f878cfa9b309394b18ed692ef1b9b73bf5f93a3f9edcb74170f1be4823a5c9ac6cde3b4e7245906e1b4e130d33eeb1c81
 DIST gnome-online-accounts-3.38.1.tar.xz 861008 BLAKE2B c66f8e59fffc69b5ad570040959fc559f788e76ba8b6b2e289b9b985c10bbb238056de39dd4e4f078ada351d38a51ab6765b4070650c97bbabc3ac1abfc3b844 SHA512 3cf38aecde3c28d51d5185f0ff7facc41191a9b6d8168ec5a8509e0e983f688607591e37fde4c75b69c5c6e2b5ac54827192eca7f41c9b7fd3e5882ccac9b155
+DIST gnome-online-accounts-3.40.0.tar.xz 860724 BLAKE2B 47f22af85b701854396c462df04b9ba2e004ee4a954619916240fef0f8139e3a37608bb9c16e4cfabbb6fc863e7448678a48865620c0293d231f9b125fe9c904 SHA512 ac90226023e2a69ad9cd12faf637844a029814282f164cc905810bf54af6693069b9019ca58211deb8487f6a32886eb072a1223fca32bc4e3fe0bc91ce8f2d6c
diff --git a/net-libs/gnome-online-accounts/gnome-online-accounts-3.40.0.ebuild b/net-libs/gnome-online-accounts/gnome-online-accounts-3.40.0.ebuild
new file mode 100644
index 000000000000..221ad9075e73
--- /dev/null
+++ b/net-libs/gnome-online-accounts/gnome-online-accounts-3.40.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="GNOME framework for accessing online accounts"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeOnlineAccounts"
+
+LICENSE="LGPL-2+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~sparc ~x86"
+
+IUSE="debug gnome +introspection kerberos +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+# pango used in goaeditablelabel
+# libsoup used in goaoauthprovider
+# goa kerberos provider is incompatible with app-crypt/heimdal, see
+# https://bugzilla.gnome.org/show_bug.cgi?id=692250
+# json-glib-0.16 needed for bug #485092
+RDEPEND="
+	>=dev-libs/glib-2.52:2
+	>=app-crypt/libsecret-0.5
+	>=dev-libs/json-glib-0.16
+	dev-libs/libxml2:2
+	>=net-libs/libsoup-2.42:2.4
+	net-libs/rest:0.7
+	>=net-libs/webkit-gtk-2.26.0:4
+	>=x11-libs/gtk+-3.19.12:3
+	x11-libs/pango
+
+	introspection? ( >=dev-libs/gobject-introspection-0.6.2:= )
+	kerberos? (
+		app-crypt/gcr:0=[gtk]
+		app-crypt/mit-krb5
+	)
+"
+# goa-daemon can launch gnome-control-center
+PDEPEND="gnome? ( >=gnome-base/gnome-control-center-3.2[gnome-online-accounts(+)] )"
+
+DEPEND="${RDEPEND}
+	vala? ( $(vala_depend) )
+	dev-libs/libxslt
+	>=dev-util/gdbus-codegen-2.30.0
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+
+	dev-libs/gobject-introspection-common
+	gnome-base/gnome-common
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# TODO: Give users a way to set the G/FB/Windows Live secrets
+	gnome2_src_configure \
+		--disable-static \
+		--enable-backend \
+		--enable-documentation \
+		--enable-exchange \
+		--enable-facebook \
+		--enable-flickr \
+		--enable-foursquare \
+		--enable-imap-smtp \
+		--enable-lastfm \
+		--enable-media-server \
+		--enable-owncloud \
+		--enable-windows-live \
+		$(usex debug --enable-debug=yes ' ') \
+		$(use_enable kerberos) \
+		$(use_enable kerberos fedora) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}