sys-apps/flatpak: Bump to version 1.10.0

Bug: https://bugs.gentoo.org/765457
Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Zac Medico <zmedico@gentoo.org>

2 files changed, 102 insertions, 0 deletions

diff --git a/sys-apps/flatpak/Manifest b/sys-apps/flatpak/Manifest
index 0441785c3a52..aec8374c97c3 100644
--- a/sys-apps/flatpak/Manifest
+++ b/sys-apps/flatpak/Manifest
@@ -1,3 +1,4 @@
+DIST flatpak-1.10.0.tar.xz 1504300 BLAKE2B 213fb5449b075250cbec9f43ea5b02afae809b8e58d3be0afd39a70d78431f7efc7912462ce46061a53aa4dc2ef8f5e9504cdaffe4b39d2f53292736442ceb3d SHA512 8eaabd66cbd26f5288fb72cddcd195ea4702243e9f5ceff425836b5f305e2b7a4172e67d30cc0e74ad97937c007e8f4ab81080a7ada3f528d05f74845c923aeb
 DIST flatpak-1.8.2.tar.xz 1424468 BLAKE2B 4ade582176cd4ed494d0afc2a75b81168dc2263183d4ec2ef731b2d3ccbd96a7cc0fdb012f07966b4429529ab69c79b32abbcc4c1a8640b030d3ba2edfbce36d SHA512 f27c05b2621328dce31e4c31ae097765864bac84f6c1fada23f48c0235c6b85f447948a07861653f7bed4e17e43f8ff3d2c60263e23426c765c787b5f447a4e2
 DIST flatpak-1.8.5.tar.xz 1430600 BLAKE2B dfa589073d3147725144c6c9c8f720a8b32918a6687a28af0f0284063e07278ece2ef191343b603e541401a5816ec095dbf3570ab7f27bba186ac416a359fbce SHA512 bdd330376e3d9ce184717692ee12f2b1ccbf1400411133ac955ea21c2d5e04ea7af9709a61ae897eae17fe258e40048576c2d829290721f349de7e6d74a9de71
 DIST flatpak-1.9.2.tar.xz 1490540 BLAKE2B 23e5c4cefaadebb1e9fd599ba8e372ddef9e7e241b186032a142f60bc07b243926d3fb514cc62e90437d2e8ddb17098476b4d73913c2ad656b2719268705057a SHA512 ab4feb6c10161a1bd92e428623772c4217ce3700db412c6280de3415247ffd39eb800dc917937529a82328d778e089f45bd0a8b48fdd7e0c8bf34c494dcb085b
diff --git a/sys-apps/flatpak/flatpak-1.10.0.ebuild b/sys-apps/flatpak/flatpak-1.10.0.ebuild
new file mode 100644
index 000000000000..6c69987f33c5
--- /dev/null
+++ b/sys-apps/flatpak/flatpak-1.10.0.ebuild
@@ -0,0 +1,101 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit autotools linux-info python-any-r1
+
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+DESCRIPTION="Linux application sandboxing and distribution framework"
+HOMEPAGE="https://flatpak.org/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="doc gtk kde introspection policykit seccomp systemd"
+RESTRICT+=" test"
+
+RDEPEND="
+	acct-group/flatpak
+	acct-user/flatpak
+	>=app-arch/libarchive-2.8:=
+	app-arch/zstd:=
+	>=app-crypt/gpgme-1.1.8:=
+	>=dev-libs/appstream-glib-0.5.10:=
+	>=dev-libs/glib-2.56:2=
+	>=dev-libs/libxml2-2.4:=
+	dev-libs/json-glib:=
+	dev-libs/libassuan:=
+	>=dev-util/ostree-2020.8:=[gpg(+)]
+	|| (
+		dev-util/ostree[curl]
+		dev-util/ostree[soup]
+	)
+	>=gnome-base/dconf-0.26:=
+	>=net-libs/libsoup-2.4:=
+	sys-apps/bubblewrap
+	sys-apps/dbus
+	>=sys-fs/fuse-2.9.9:0=
+	sys-apps/xdg-dbus-proxy
+	x11-apps/xauth
+	x11-libs/gdk-pixbuf:2=
+	x11-libs/libXau:=
+	policykit? ( >=sys-auth/polkit-0.98:= )
+	seccomp? ( sys-libs/libseccomp:= )
+	systemd? ( sys-apps/systemd:= )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/automake-1.13.4
+	>=sys-devel/gettext-0.18.2
+	virtual/pkgconfig
+	dev-util/gdbus-codegen
+	sys-devel/bison
+	introspection? ( >=dev-libs/gobject-introspection-1.40 )
+	doc? (
+		>=dev-util/gtk-doc-1.20
+		dev-libs/libxslt
+	)
+	$(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
+"
+
+PDEPEND="
+	gtk? ( sys-apps/xdg-desktop-portal-gtk )
+	kde? ( kde-plasma/xdg-desktop-portal-kde )
+"
+
+python_check_deps() {
+	has_version -b "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	local CONFIG_CHECK="~USER_NS"
+	linux-info_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	# This line fails because locales are in /usr/lib/locale/locale-archive.
+	sed -i 's:^cp -r /usr/lib/locale/C.*:#\0:' tests/make-test-runtime.sh || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-sandboxed-triggers
+		--enable-xauth
+		--localstatedir="${EPREFIX}"/var
+		--with-system-bubblewrap
+		--with-system-dbus-proxy
+		$(use_enable doc documentation)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable policykit system-helper)
+		$(use_enable seccomp)
+		$(use_with systemd)
+	)
+
+	econf "${myeconfargs[@]}"
+}