x11-misc/kaqaz: update EAPI 7 -> 8, drop unused dev-qt/qtsensors

Build system actually is not wired up to build those parts using it.

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/x11-misc/kaqaz/kaqaz-1.2.0-r5.ebuild b/x11-misc/kaqaz/kaqaz-1.2.0-r5.ebuild
new file mode 100644
index 000000000000..3c58668d1b08
--- /dev/null
+++ b/x11-misc/kaqaz/kaqaz-1.2.0-r5.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qmake-utils
+
+DESCRIPTION="Note manager"
+HOMEPAGE="https://github.com/sialan-labs/kaqaz/"
+SRC_URI="https://github.com/sialan-labs/kaqaz/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtdeclarative:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5[qml]
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtpositioning:5
+	dev-qt/qtsingleapplication[X]
+	dev-qt/qtsql:5[sqlite]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+"
+RDEPEND="${DEPEND}
+	dev-qt/qtgraphicaleffects:5
+	dev-qt/qtquickcontrols:5
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-qt55.patch"
+	"${FILESDIR}/${P}-unbundle-qtsingleapplication.patch"
+)
+
+src_prepare() {
+	default
+	rm -r sialantools/qtsingleapplication || die
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	emake install INSTALL_ROOT="${D}"
+}