3 files changed, 0 insertions, 577 deletions
diff --git a/dev-libs/efl/Manifest b/dev-libs/efl/Manifest
index 795c1428528e..bdc69d0b4f66 100644
--- a/dev-libs/efl/Manifest
+++ b/dev-libs/efl/Manifest
@@ -1,5 +1,3 @@
 DIST efl-1.22.2.tar.xz 71320272 BLAKE2B b1eb66228ec5a92f5d89bf38d95439f9bfb0b09a074e418094474d7c7d0de6a4ae998321a02273a5c9bbcfcba260a7ff3d8cef0af445293869c82c57dec2cca0 SHA512 7385b1fdeee0a4565a0765fedbe5cecca81b86b306ee95a703b3064a88427ab0b4967f6f075a92f5c1d5911cefc56a9c2d45c7347572480169e3f53348321734
-DIST efl-1.22.5.tar.xz 71358856 BLAKE2B d1b9c8263608bca61760adb129eb5ad3d507caaa2d4e03847d9c06c99494d6dcaa0756368f700fde64d15dd33147a1f58f5391164902c1f9f586ef7307b14510 SHA512 87d10ab244778fc8452ea85cbf698a6b0ccd065964941f7c04d073cf7db9632b09d7956d86bd5c4e9fa102efceb1057269322e84504c70ee5f740176cd4bb26f
 DIST efl-1.22.6.tar.xz 70641848 BLAKE2B a6644f25934d3c9776b06edd7a9ffc321da42ee039b703c1af317d14e757b489c6d42add281febde5e81b48e38fbfa31f5b201ade4d27cd50cc70d16b9028fdd SHA512 adf2b9275c295b61928134ce1af53d8830b46815d8ba09d221c7659b8a2aed6e4593b35919a98f0e33ec9b7930c5b09de8e6680536cccb21c551908b25158f56
-DIST efl-1.23.0.tar.xz 77467596 BLAKE2B a07d988623d1b743bad02803f870b8b2cbf9e629b78c7614a733cb916ef2ab585d855396eda62949ae9dd55d2efd99f38c11fc11bdc7eccead6c727baa279a0e SHA512 6f96b822a8e8d44309b6174f2bde66aec8cce94386574e61fac88ab539113fec173e7f00db16a03d83b7294f5d4892800861cfda2f2b72bb78636a781bfd21b3
 DIST efl-1.23.1.tar.xz 77466768 BLAKE2B a8507777f84ee356bb53982d2b102eb6413ab274ce98dbd87b62a11b6a89eb7d12e0d858b5dfcbbe3da0e1bcc753c338d4c4b7060c569ee621e71afa2477397d SHA512 9c81f28bb0d87e1a3e5d2204c0e2401d9b3f6dcc34f47cb2b41711ef033b3134f4cd283e87a216a0ce4ee903f721a1f8c2f003577444c5781e7f47ce827201e6
diff --git a/dev-libs/efl/efl-1.22.5.ebuild b/dev-libs/efl/efl-1.22.5.ebuild
deleted file mode 100644
index 5af4a6a9437b..000000000000
--- a/dev-libs/efl/efl-1.22.5.ebuild
+++ /dev/null
@@ -1,282 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit pax-utils xdg-utils
-
-DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
-HOMEPAGE="https://www.enlightenment.org"
-SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${P}.tar.xz"
-
-LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
-IUSE="+bmp dds connman debug drm +eet elogind examples fbcon +fontconfig fribidi gif gles2 glib gnutls gstreamer harfbuzz hyphen +ico ibus jpeg2k libressl libuv luajit neon nls opengl ssl pdf physics postscript +ppm +psd pulseaudio raw scim sdl sound static-libs svg +system-lz4 systemd tga tiff tslib unwind v4l valgrind vlc vnc wayland webp X xcf xim xine xpm xpresent zeroconf"
-
-REQUIRED_USE="
-	?? ( elogind systemd )
-	?? ( gles2 opengl )
-	fbcon? ( !tslib )
-	gles2? (
-		|| ( wayland X )
-		!sdl
-	)
-	ibus? ( glib )
-	opengl? ( X )
-	pulseaudio? ( sound )
-	sdl? ( opengl )
-	vnc? ( fbcon X )
-	wayland? ( gles2 !opengl )
-	xim? ( X )
-	xpresent? ( X )
-"
-
-RDEPEND="
-	net-misc/curl
-	media-libs/libpng:0=
-	sys-apps/dbus
-	sys-apps/util-linux
-	virtual/jpeg:0=
-	connman? ( net-misc/connman )
-	drm? (
-		dev-libs/libinput
-		media-libs/mesa[gbm]
-		x11-libs/libdrm
-		x11-libs/libxkbcommon
-	)
-	elogind? ( sys-auth/elogind )
-	fontconfig? ( media-libs/fontconfig )
-	fribidi? ( dev-libs/fribidi )
-	gif? ( media-libs/giflib:= )
-	gles2? ( media-libs/mesa[egl,gles2] )
-	glib? ( dev-libs/glib:2 )
-	gstreamer? (
-		media-libs/gstreamer:1.0
-		media-libs/gst-plugins-base:1.0
-	)
-	harfbuzz? ( media-libs/harfbuzz )
-	hyphen? ( dev-libs/hyphen )
-	ibus? ( app-i18n/ibus )
-	jpeg2k? ( media-libs/openjpeg:= )
-	libuv? ( dev-libs/libuv )
-	luajit? ( dev-lang/luajit:= )
-	!luajit? ( dev-lang/lua:* )
-	pdf? ( app-text/poppler:=[cxx] )
-	physics? ( sci-physics/bullet:= )
-	postscript? ( app-text/libspectre )
-	pulseaudio? ( media-sound/pulseaudio )
-	raw? ( media-libs/libraw:= )
-	scim? ( app-i18n/scim )
-	sdl? (
-		media-libs/libsdl2
-		virtual/opengl
-	)
-	sound? ( media-libs/libsndfile )
-	ssl? (
-		gnutls? ( net-libs/gnutls:= )
-		!gnutls? (
-			!libressl? ( dev-libs/openssl:0= )
-			libressl? ( dev-libs/libressl:= )
-		)
-	)
-	svg? (
-		gnome-base/librsvg
-		x11-libs/cairo
-	)
-	system-lz4? ( app-arch/lz4 )
-	systemd? ( sys-apps/systemd:= )
-	tiff? ( media-libs/tiff:0= )
-	tslib? ( x11-libs/tslib:= )
-	unwind? ( sys-libs/libunwind )
-	valgrind? ( dev-util/valgrind )
-	vlc? ( media-video/vlc )
-	vnc? ( net-libs/libvncserver )
-	wayland? (
-		dev-libs/wayland
-		media-libs/mesa[gles2,wayland]
-		x11-libs/libxkbcommon
-	)
-	webp? ( media-libs/libwebp:= )
-	X? (
-		media-libs/freetype
-		x11-libs/libXcursor
-		x11-libs/libX11
-		x11-libs/libXcomposite
-		x11-libs/libXdamage
-		x11-libs/libXext
-		x11-libs/libXfixes
-		x11-libs/libXinerama
-		x11-libs/libXrandr
-		x11-libs/libXrender
-		x11-libs/libXtst
-		x11-libs/libXScrnSaver
-		gles2? (
-			x11-libs/libX11
-			x11-libs/libXrender
-			virtual/opengl
-		)
-		opengl? (
-			x11-libs/libX11
-			x11-libs/libXrender
-			virtual/opengl
-		)
-		wayland? ( x11-libs/libxkbcommon[X] )
-	)
-	xine? ( media-libs/xine-lib )
-	xpm? ( x11-libs/libXpm )
-	xpresent? ( x11-libs/libXpresent )
-	zeroconf? ( net-dns/avahi )
-"
-
-DEPEND="${RDEPEND}"
-BDEPEND="virtual/pkgconfig
-	nls? ( sys-devel/gettext )"
-
-src_prepare() {
-	default
-
-	# Upstream still doesnt offer a configure flag. #611108
-	if ! use unwind ; then
-		sed -i -e 's:libunwind libunwind-generic:xxxxxxxxxxxxxxxx:' \
-		configure || die "Sedding configure file with unwind fix failed."
-	fi
-}
-
-src_configure() {
-	local myconf=(
-		--enable-cxx-bindings
-		--enable-image-loader-generic
-		--enable-image-loader-jpeg
-		--enable-image-loader-png
-		--enable-libeeze
-		--enable-libmount
-		--enable-quick-launch
-		--enable-threads
-		--enable-xinput22
-
-		--disable-cancel-ok
-		--disable-cocoa
-		--disable-csharp-beta
-		--disable-csharp-bindings
-		--disable-doc
-		--disable-ecore-buffer
-		--disable-ecore-drm
-		--disable-ecore-wayland
-		--disable-eglfs
-		--disable-g-main-loop
-		--disable-gesture
-		--disable-gstreamer
-		--disable-pixman
-		--disable-tizen
-		--disable-wayland-ivi-shell
-
-		$(use_enable bmp image-loader-bmp)
-		$(use_enable bmp image-loader-wbmp)
-		$(use_enable dds image-loader-dds)
-		$(use_enable drm)
-		$(use_enable drm elput)
-		$(use_enable eet image-loader-eet)
-		$(use_enable elogind)
-		$(use_enable examples always-build-examples)
-		$(use_enable fbcon fb)
-		$(use_enable fontconfig)
-		$(use_enable fribidi)
-		$(use_enable gif image-loader-gif)
-		$(use_enable gles2 egl)
-		$(use_enable gstreamer gstreamer1)
-		$(use_enable harfbuzz)
-		$(use_enable hyphen)
-		$(use_enable ico image-loader-ico)
-		$(use_enable ibus)
-		$(use_enable jpeg2k image-loader-jp2k)
-		$(use_enable libuv)
-		$(use_enable !luajit lua-old)
-		$(use_enable neon)
-		$(use_enable nls)
-		$(use_enable pdf poppler)
-		$(use_enable physics)
-		$(use_enable postscript spectre)
-		$(use_enable ppm image-loader-pmaps)
-		$(use_enable psd image-loader-psd)
-		$(use_enable pulseaudio)
-		$(use_enable raw libraw)
-		$(use_enable scim)
-		$(use_enable sdl)
-		$(use_enable sound audio)
-		$(use_enable static-libs static)
-		$(use_enable svg librsvg)
-		$(use_enable system-lz4 liblz4)
-		$(use_enable systemd)
-		$(use_enable tga image-loader-tga)
-		$(use_enable tiff image-loader-tiff)
-		$(use_enable tslib)
-		$(use_enable v4l v4l2)
-		$(use_enable valgrind)
-		$(use_enable vlc libvlc)
-		$(use_enable vnc vnc-server)
-		$(use_enable wayland)
-		$(use_enable webp image-loader-webp)
-		$(use_enable xcf)
-		$(use_enable xim)
-		$(use_enable xine)
-		$(use_enable xpm image-loader-xpm)
-		$(use_enable xpresent)
-		$(use_enable zeroconf avahi)
-
-		--with-crypto=$(usex gnutls gnutls $(usex ssl openssl none))
-		--with-glib=$(usex glib)
-		--with-js=none
-		--with-net-control=$(usex connman connman none)
-		--with-profile=$(usex debug debug release)
-		--with-x11=$(usex X xlib none)
-
-		$(use_with X x)
-	)
-
-	use drm && use wayland && myconf+=( --enable-gl-drm )
-
-	if use opengl ; then
-		myconf+=( --with-opengl=full )
-	elif use gles2 ; then
-		myconf+=( --with-opengl=es )
-	elif use drm && use wayland ; then
-		myconf+=( --with-opengl=es )
-	else
-		myconf+=( --with-opengl=none )
-	fi
-
-	econf "${myconf[@]}"
-}
-
-src_compile() {
-	if host-is-pax && use luajit ; then
-		# We need to build the lua code first so we can pax-mark it. #547076
-		local target='_e_built_sources_target_gogogo_'
-		printf '%s: $(BUILT_SOURCES)\n' "${target}" >> src/Makefile || die
-		emake -C src "${target}"
-		emake -C src bin/elua/elua
-		pax-mark m src/bin/elua/.libs/elua
-	fi
-
-	V=1 emake
-}
-
-src_install() {
-	V=1 emake install DESTDIR="${D}"
-	einstalldocs
-
-	if ! use static-libs ; then
-		find "${D}" -name '*.la' -delete || die
-	fi
-}
-
-pkg_postinst() {
-	xdg_icon_cache_update
-	xdg_mimeinfo_database_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-	xdg_mimeinfo_database_update
-}
diff --git a/dev-libs/efl/efl-1.23.0.ebuild b/dev-libs/efl/efl-1.23.0.ebuild
deleted file mode 100644
index 69391eedd1d0..000000000000
--- a/dev-libs/efl/efl-1.23.0.ebuild
+++ /dev/null
@@ -1,293 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit meson xdg-utils
-
-DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
-HOMEPAGE="https://www.enlightenment.org"
-SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${P}.tar.xz"
-
-LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
-SLOT="0"
-KEYWORDS="~amd64 ~hppa ~x86"
-IUSE="X bmp connman dds debug doc +drm +eet elogind examples fbcon fontconfig
-	fribidi gif gles2 gnutls glib +gstreamer harfbuzz hyphen ibus ico libressl
-	lua +luajit jpeg2k json nls mono opengl +pdf physics pmaps postscript psd
-	pulseaudio raw scim sdl +sound +ssl static-libs +svg +system-lz4 systemd
-	tga tgv tiff tslib unwind v4l vlc vnc wayland webp xcf xim xine xpm
-	xpresent zeroconf"
-
-REQUIRED_USE="
-	?? ( elogind systemd )
-	?? ( gles2 opengl )
-	^^ ( lua luajit )
-	ssl
-	gles2? ( || ( wayland X ) )
-	pulseaudio? ( sound )
-	wayland? ( gles2 !opengl )
-	xim? ( X )
-	xpresent? ( X )
-"
-
-# Requires everything to be enabled unconditionally.
-RESTRICT="test"
-
-RDEPEND="
-	dev-libs/check
-	net-misc/curl
-	media-libs/libpng:0=
-	sys-libs/zlib
-	virtual/jpeg:0=
-	X? (
-		media-libs/freetype
-		x11-libs/libX11
-		x11-libs/libXcomposite
-		x11-libs/libXcursor
-		x11-libs/libXdamage
-		x11-libs/libXdmcp
-		x11-libs/libXext
-		x11-libs/libXfixes
-		x11-libs/libXi
-		x11-libs/libXinerama
-		x11-libs/libXrandr
-		x11-libs/libXrender
-		x11-libs/libXtst
-		x11-libs/libXScrnSaver
-		wayland? ( x11-libs/libxkbcommon[X] )
-	)
-	connman? ( net-misc/connman )
-	drm? (
-		dev-libs/libinput
-		dev-libs/wayland
-		media-libs/mesa[gbm]
-		x11-libs/libdrm
-		x11-libs/libxkbcommon
-	)
-	elogind? (
-		sys-auth/elogind
-		virtual/libudev
-	)
-	fontconfig? ( media-libs/fontconfig )
-	fribidi? ( dev-libs/fribidi )
-	gif? ( media-libs/giflib:= )
-	gles2? (
-		media-libs/mesa[egl,gles2]
-		virtual/opengl
-	)
-	glib? ( dev-libs/glib:2 )
-	gstreamer? (
-		media-libs/gstreamer:1.0
-		media-libs/gst-plugins-base:1.0
-	)
-	hyphen? ( dev-libs/hyphen )
-	ibus? ( app-i18n/ibus )
-	jpeg2k? ( media-libs/openjpeg:= )
-	json? ( dev-libs/rlottie )
-	lua? ( dev-lang/lua:* )
-	luajit? ( dev-lang/luajit:* )
-	mono? ( dev-lang/mono )
-	opengl? ( virtual/opengl )
-	pdf? ( app-text/poppler:=[cxx] )
-	physics? ( sci-physics/bullet:= )
-	postscript? ( app-text/libspectre )
-	pulseaudio? ( media-sound/pulseaudio )
-	raw? ( media-libs/libraw:= )
-	scim? ( app-i18n/scim )
-	sdl? ( media-libs/libsdl2 )
-	sound? ( media-libs/libsndfile )
-	ssl? (
-		gnutls? ( net-libs/gnutls:= )
-		!gnutls? (
-			!libressl? ( dev-libs/openssl:0= )
-			libressl? ( dev-libs/libressl:= )
-		)
-	)
-	svg? ( gnome-base/librsvg )
-	system-lz4? ( app-arch/lz4 )
-	systemd? ( sys-apps/systemd:= )
-	tiff? ( media-libs/tiff:0= )
-	tslib? ( x11-libs/tslib:= )
-	unwind? ( sys-libs/libunwind )
-	v4l? ( media-libs/libv4l )
-	vlc? ( media-video/vlc )
-	vnc? ( net-libs/libvncserver )
-	wayland? (
-		dev-libs/wayland
-		media-libs/mesa[gles2,wayland]
-		x11-libs/libxkbcommon
-	)
-	webp? ( media-libs/libwebp:= )
-	xine? ( media-libs/xine-lib )
-	xpm? ( x11-libs/libXpm )
-	xpresent? ( x11-libs/libXpresent )
-	zeroconf? ( net-dns/avahi )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="virtual/pkgconfig
-	doc? ( app-doc/doxygen )
-	nls? ( sys-devel/gettext )"
-
-src_configure() {
-	local emesonargs=(
-		--buildtype=release
-
-		-D buffer=false
-		-D cocoa=false
-		-D drm-deprecated=false
-		-D g-mainloop=false
-		-D install-eo-files=false
-		-D mono-beta=false
-		-D pixman=false
-		-D wl-deprecated=false
-		-D xgesture=false
-
-		-D edje-sound-and-video=true
-		-D eeze=true
-		-D libmount=true
-		-D native-arch-optimization=true
-		-D xinput2=true
-		-D xinput22=true
-
-		$(meson_use X x11)
-		$(meson_use drm)
-		$(meson_use elogind)
-		$(meson_use examples build-examples)
-		$(meson_use fbcon fb)
-		$(meson_use fontconfig)
-		$(meson_use fribidi)
-		$(meson_use glib)
-		$(meson_use gstreamer)
-		$(meson_use harfbuzz)
-		$(meson_use hyphen)
-		$(meson_use luajit elua)
-		$(meson_use nls)
-		$(meson_use physics)
-		$(meson_use pulseaudio)
-		$(meson_use sdl)
-		$(meson_use sound audio)
-		$(meson_use systemd)
-		$(meson_use tslib)
-		$(meson_use v4l v4l2)
-		$(meson_use vnc vnc-server)
-		$(meson_use wayland wl)
-		$(meson_use xpresent)
-		$(meson_use zeroconf avahi)
-
-		$(meson_use !system-lz4 embedded-lz4)
-	)
-
-	if use opengl; then
-		emesonargs+=( -D opengl=full )
-	elif use gles2; then
-		emesonargs+=( -D opengl=es-egl )
-	else
-		emesonargs+=( -D opengl=none )
-	fi
-
-	if use gnutls; then
-		emesonargs+=( -D crypto=gnutls )
-	else
-		emesonargs+=( -D crypto=openssl )
-	fi
-
-	if use connman; then
-		emesonargs+=( -D network-backend=connman )
-	else
-		emesonargs+=( -D network-backend=none )
-	fi
-
-	if use static-libs; then
-		emesonargs+=( -D evas-modules=static )
-	else
-		emesonargs+=( -D evas-modules=shared )
-	fi
-
-	local disabledEvasLoaders=""
-	! use bmp && disabledEvasLoaders+="bmp,wbmp,"
-	! use dds && disabledEvasLoaders+="dds,"
-	! use eet && disabledEvasLoaders+="eet,"
-	! use gif && disabledEvasLoaders+="gif,"
-	! use gstreamer && disabledEvasLoaders+="gst,"
-	! use ico && disabledEvasLoaders+="ico,"
-	! use jpeg2k && disabledEvasLoaders+="jp2k,"
-	! use json && disabledEvasLoaders+="json,"
-	! use pdf && disabledEvasLoaders+="pdf,"
-	! use pmaps && disabledEvasLoaders+="pmaps,"
-	! use postscript && disabledEvasLoaders+="ps,"
-	! use psd && disabledEvasLoaders+="psd,"
-	! use raw && disabledEvasLoaders+="raw,"
-	! use svg && disabledEvasLoaders+="rsvg,svg,"
-	! use tga && disabledEvasLoaders+="tga,"
-	! use tgv && disabledEvasLoaders+="tgv,"
-	! use tiff && disabledEvasLoaders+="tiff,"
-	! use webp && disabledEvasLoaders+="webp,"
-	! use xcf && disabledEvasLoaders+="xcf,"
-	! use xpm && disabledEvasLoaders+="xpm,"
-	[[ ! -z "$disabledEvasLoaders" ]] && disabledEvasLoaders=${disabledEvasLoaders::-1}
-	emesonargs+=( -D evas-loaders-disabler="${disabledEvasLoaders}" )
-
-	local disabledImfLoaders=""
-	! use ibus && disabledImfLoaders+="ibus,"
-	! use scim && disabledImfLoaders+="scim,"
-	! use xim && disabledImfLoaders+="xim,"
-	[[ ! -z "$disabledImfLoaders" ]] && disabledImfLoaders=${disabledImfLoaders::-1}
-	emesonargs+=( -D ecore-imf-loaders-disabler="${disabledImfLoaders}" )
-
-	local disabledEmotionLoaders="gstreamer,"
-	! use gstreamer && disabledEmotionLoaders+="gstreamer1,"
-	! use vlc && disabledEmotionLoaders+="libvlc,"
-	! use xine && disabledEmotionLoaders+="xine,"
-	disabledEmotionLoaders=${disabledEmotionLoaders::-1}
-	emesonargs+=( -D emotion-loaders-disabler="${disabledEmotionLoaders}" )
-
-	local disabledGenericEmotionLoaders=""
-	! use vlc && disabledGenericEmotionLoaders+="vlc"
-	emesonargs+=( -D emotion-generic-loaders-disabler="${disabledGenericEmotionLoaders}" )
-
-	local bindingsList="cxx,"
-	use luajit && bindingsList+="luajit,"
-	use mono && bindingsList+="mono,"
-	[[ ! -z "$bindingsList" ]] && bindingsList=${bindingsList::-1}
-	emesonargs+=( -D bindings="${bindingsList}" )
-
-	local luaChoice=""
-	if use luajit; then
-		luaChoice+="luajit"
-	else
-		luaChoice+="lua"
-	fi
-	emesonargs+=( -D lua-interpreter="${luaChoice}" )
-
-	meson_src_configure
-}
-
-src_compile() {
-	meson_src_compile
-
-	if use doc; then
-		cd doc/ || die "Failed to switch into doc/ dir."
-		doxygen . || die "Doxygen failed to run."
-	fi
-}
-
-src_install() {
-	use doc && local HTML_DOCS=( "${S}"/doc/html/. )
-	meson_src_install
-
-	if use examples; then
-		insinto /usr/share/doc/${PF}/examples/
-		doins -r "${BUILD_DIR}"/src/examples/.
-	fi
-}
-
-pkg_postinst() {
-	xdg_icon_cache_update
-	xdg_mimeinfo_database_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-	xdg_mimeinfo_database_update
-}