2 files changed, 90 insertions, 0 deletions
diff --git a/www-apache/mod_gnutls/Manifest b/www-apache/mod_gnutls/Manifest
index e8db9e5a3d09..3b98de5a5882 100644
--- a/www-apache/mod_gnutls/Manifest
+++ b/www-apache/mod_gnutls/Manifest
@@ -1 +1,2 @@
 DIST mod_gnutls-0.11.0.tar.bz2 458966 BLAKE2B 6d81be7b7d48255173d028a8e3207badbce0c1ba541124a241b63d4ed4eb36833156e9cd7194318138b6f16667a971d5311d56b9b0036e5b3d9dac8d352a4335 SHA512 090d244823f15a6b23dd2ad9b35db202ebbe96210ec8fd06e06f13e32c327e9d9a449834c899755f1ec8c1a3a71db1b125d436ce661caee1002a8719b4c1320e
+DIST mod_gnutls-0.12.0.tar.bz2 461643 BLAKE2B ffbb4bd50cae7c974c59067908712e104e6d77b121e5e6114a1a45279b9396331f353a53ddae8e3d58259cd7669f047edc4d2b5ebebe94bb40df55f3546b0a02 SHA512 1ec32d0641dc8dc520726a4439edf2e9dbe582651aa4c782047d0499e5e7418b3145eb071d9e97aa4ec803e6818974efea2ed8ed18e5062cd7fdb90ef2e9e0f2
diff --git a/www-apache/mod_gnutls/mod_gnutls-0.12.0.ebuild b/www-apache/mod_gnutls/mod_gnutls-0.12.0.ebuild
new file mode 100644
index 000000000000..7d8c03acc123
--- /dev/null
+++ b/www-apache/mod_gnutls/mod_gnutls-0.12.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit autotools apache-module python-any-r1
+
+DESCRIPTION="mod_gnutls uses GnuTLS for SSL/TLS encryption in Apache2 (compare to mod_ssl)"
+HOMEPAGE="https://mod.gnutls.org/"
+SRC_URI="https://mod.gnutls.org/downloads/${P}.tar.bz2"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+CDEPEND=">=net-libs/gnutls-3.3.0:=[pkcs11]"
+
+TEST_REQUIRED_APACHE_MODULES="apache2_modules_proxy,apache2_modules_proxy_http"
+
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	$(python_gen_any_dep '
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+	')
+	test? (
+		app-crypt/monkeysphere
+		>=net-libs/gnutls-3.3.0:=[tools]
+		net-misc/curl
+		|| (
+			www-servers/apache[apache2_mpms_worker,${TEST_REQUIRED_APACHE_MODULES}]
+			www-servers/apache[apache2_mpms_prefork,${TEST_REQUIRED_APACHE_MODULES}]
+			www-servers/apache[apache2_mpms_event,${TEST_REQUIRED_APACHE_MODULES}]
+		)
+	)"
+
+RDEPEND="${CDEPEND}"
+
+RESTRICT="!test? ( test )"
+
+APACHE2_MOD_CONF="47_${PN}"
+APACHE2_MOD_DEFINE="GNUTLS"
+
+DOCFILES="CHANGELOG NOTICE README"
+
+need_apache2_4
+
+python_check_deps() {
+	has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	# Calling depend.apache_pkg_setup fails because we do not have
+	# "apache2" in IUSE but the function expects this in order to call
+	# _init_apache2_late which sets the APACHE_MODULESDIR variable.
+	_init_apache2
+	_init_apache2_late
+
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-apxs="${APXS}"
+		--disable-strict
+		--disable-doxygen-dot
+		--disable-doxygen-doc
+		--disable-doxygen-html
+		--disable-doxygen-pdf
+		--disable-valgrind-test
+		ac_cv_path_UNSHARE=no
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake
+}
+
+src_install() {
+	apache-module_src_install
+}