From 4c29238d67ab0f60f97a98a61ebf2d1741623864 Mon Sep 17 00:00:00 2001
From: Michael Weber <xmw@gentoo.org>
Date: Sun, 28 Jan 2018 14:30:24 +0100
Subject: app-text/llpp: Version bump to git version for mupdf-1.12.

Package-Manager: Portage-2.3.20, Repoman-2.3.6
---
 app-text/llpp/Manifest                  |  1 +
 app-text/llpp/llpp-26b.ebuild           |  3 +-
 app-text/llpp/llpp-26b_p20180114.ebuild | 86 +++++++++++++++++++++++++++++++++
 3 files changed, 89 insertions(+), 1 deletion(-)
 create mode 100644 app-text/llpp/llpp-26b_p20180114.ebuild

(limited to 'app-text')

diff --git a/app-text/llpp/Manifest b/app-text/llpp/Manifest
index c382b3ba98a1..c1cd1df56112 100644
--- a/app-text/llpp/Manifest
+++ b/app-text/llpp/Manifest
@@ -1 +1,2 @@
 DIST llpp-26b.tar.gz 169385 BLAKE2B 9a80c22d013af063e3908bda69108ce6a4e0f72efb1c0b930308591d2b8a0f94f7b71a5f1057543e102b95b01440d567e6648d1ed77f1e85728f5ea31718ea28 SHA512 ce7d743d8ec998a93cf272083dc5926ce6a250aee6ac768814f511ecb309ffe94fb0e2561ca1778e1c7fbd5824545477937618c8e66d32fd273f9b5e5e3fd143
+DIST llpp-26b_p20180114.tar.gz 170204 BLAKE2B c7f46491d69350e8e94b444f0be4d7375f5658cccded792ecce2a246c907ae98bcca45d73e3b6c15765bd926d559327491559b5e5eec63bf2645cba84f6ee0d3 SHA512 1bc544f4bae268f573c2c111b69f7129bd3d1c1c8cc635c06f76e12670ad9476b4c2a2776e3959203ab6e53ea8ad1c68be290619298f7ebc1ae8203875f88314
diff --git a/app-text/llpp/llpp-26b.ebuild b/app-text/llpp/llpp-26b.ebuild
index a597bef81e81..607103b2b3e5 100644
--- a/app-text/llpp/llpp-26b.ebuild
+++ b/app-text/llpp/llpp-26b.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -15,6 +15,7 @@ KEYWORDS="amd64 ppc x86"
 IUSE="+ocamlopt static"
 
 LIB_DEPEND=">=app-text/mupdf-1.11:0=[static-libs]
+	<app-text/mupdf-1.12:0=[static-libs]
 	media-libs/openjpeg:2[static-libs]
 	media-libs/fontconfig:1.0[static-libs]
 	media-libs/freetype:2[static-libs]
diff --git a/app-text/llpp/llpp-26b_p20180114.ebuild b/app-text/llpp/llpp-26b_p20180114.ebuild
new file mode 100644
index 000000000000..296e6579cdbd
--- /dev/null
+++ b/app-text/llpp/llpp-26b_p20180114.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils multilib toolchain-funcs vcs-snapshot
+
+DESCRIPTION="graphical PDF viewer which aims to superficially resemble less(1)"
+HOMEPAGE="http://repo.or.cz/w/llpp.git"
+SRC_URI="https://distfiles.gentoo.org/distfiles/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="+ocamlopt static"
+
+LIB_DEPEND=">=app-text/mupdf-1.12.0:0=[static-libs]
+	media-libs/openjpeg:2[static-libs]
+	media-libs/fontconfig:1.0[static-libs]
+	media-libs/freetype:2[static-libs]
+	media-libs/jbig2dec[static-libs]
+	sys-libs/zlib[static-libs]
+	virtual/jpeg:0[static-libs]
+	x11-libs/libX11[static-libs]"
+RDEPEND="x11-misc/xsel
+	!static? ( ${LIB_DEPEND//\[static-libs]} )"
+DEPEND="${RDEPEND}
+	static? ( ${LIB_DEPEND}
+		app-arch/bzip2[static-libs]
+		media-libs/libXcm[static-libs]
+		x11-libs/libXau[static-libs]
+		x11-libs/libXdmcp[static-libs]
+		x11-libs/libXmu[static-libs] )
+	>=dev-lang/ocaml-4.02[ocamlopt?]
+	dev-ml/lablgl[glut,ocamlopt?]"
+
+RESTRICT="!ocamlopt? ( strip )"
+
+PATCHES=( "${FILESDIR}"/${PN}-26b-WM_CLASS.patch )
+
+src_compile() {
+	local ocaml=$(usex ocamlopt ocamlopt.opt ocamlc.opt)
+	local cmo=$(usex ocamlopt cmx cmo)
+	local cma=$(usex ocamlopt cmxa cma)
+	local ccopt="$(freetype-config --cflags ) -O -include ft2build.h -D_GNU_SOURCE -DUSE_FONTCONFIG -std=c99 -Wextra -Wall -pedantic-errors -Wunused-parameter -Wsign-compare -Wshadow"
+	if use static ; then
+		local cclib=""
+		local slib=""
+		local spath=( ${EROOT}usr/$(get_libdir) $($(tc-getPKG_CONFIG) --libs-only-L --static mupdf x11 ${egl} | sed 's:-L::g') )
+		for slib in $($(tc-getPKG_CONFIG) --libs-only-l --static mupdf x11 ${egl} fontconfig) -ljpeg -ljbig2dec ; do
+			case ${slib} in
+				-lm|-ldl|-lpthread)
+					einfo "${slib}: shared"
+					cclib+="${slib} " ;;
+				*)
+					local ccnew=$(find ${spath} -name "lib${slib/-l}.a")
+					einfo "${slib}: use ${ccnew}"
+					cclib+="${ccnew} " ;;
+			esac
+		done
+	else
+		local cclib="$($(tc-getPKG_CONFIG) --libs mupdf x11 ${egl} fontconfig) -lpthread"
+	fi
+
+	verbose() { echo "$@" >&2 ; "$@" || die ; }
+	verbose sh mkhelp.sh KEYS ${PV} > help.ml
+	verbose printf 'let version ="%s";;\n' ${PV} >> help.ml
+	verbose ${ocaml} -c -o link.o -ccopt "${ccopt}" link.c
+	verbose ${ocaml} -c -o keys.${cmo} keys.ml
+	verbose ${ocaml} -c -o help.${cmo} help.ml
+	verbose ${ocaml} -c -o utils.${cmo} utils.ml
+	verbose ${ocaml} -c -o wsi/x11/wsi.cmi wsi/x11/wsi.mli
+	verbose ${ocaml} -c -o wsi/x11/wsi.${cmo} -I wsi/x11 wsi/x11/wsi.ml
+	verbose ${ocaml} -c -o parser.${cmo} parser.ml
+	verbose ${ocaml} -c -o config.${cmo} -I +lablGL -I wsi/x11 config.ml
+	verbose ${ocaml} -c -o main.${cmo} -I +lablGL -I wsi/x11 main.ml
+	verbose ${ocaml} $(usex ocamlopt "" -custom) -o llpp -I +lablGL -I wsi/x11 \
+		str.${cma} unix.${cma} lablgl.${cma} link.o \
+	    -cclib "${cclib}" \
+		help.${cmo} utils.${cmo} parser.${cmo} wsi.${cmo} config.${cmo} main.${cmo}
+}
+
+src_install() {
+	dobin ${PN} misc/${PN}ac
+	dodoc KEYS README Thanks
+}
-- 
cgit v1.2.3-65-gdbad