From 70f96e4b929602b95d7eb53f79d3d5087a51b5bf Mon Sep 17 00:00:00 2001
From: Ben Kohler <bkohler@gentoo.org>
Date: Thu, 25 May 2023 08:05:33 -0500
Subject: dev-libs/ell: add 0.57

Signed-off-by: Ben Kohler <bkohler@gentoo.org>
---
 dev-libs/ell/Manifest        |  1 +
 dev-libs/ell/ell-0.57.ebuild | 54 ++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 55 insertions(+)
 create mode 100644 dev-libs/ell/ell-0.57.ebuild

(limited to 'dev-libs/ell')

diff --git a/dev-libs/ell/Manifest b/dev-libs/ell/Manifest
index 2b0985224ee6..9d589fc7ddad 100644
--- a/dev-libs/ell/Manifest
+++ b/dev-libs/ell/Manifest
@@ -1 +1,2 @@
 DIST ell-0.56.tar.xz 563096 BLAKE2B 3be874ddddab558911d5ea4e4fb0b32c1557b8577435f39ee88d7302bbb0efbd24671f6c426bbeaba2704ba45b865320e6f2e31f6a9c4d86e82dc8ed38ebae9f SHA512 7255470331927f67ebd1297e6c524c9c244234cf00923016c77d90bad5e4e381605c70373a7be4ecf9c1e72ec85fbc1671960dd31fb6eec279f2299e81c66ac1
+DIST ell-0.57.tar.xz 563996 BLAKE2B 6fec30dc6994656b4a266cddaaf5984c3bcdb06b8b80d432b772f5c2a3166f2f3a4dca7ce1d44857901150a17f17be595606e535ef4ca0cb97476effbb6342cc SHA512 6dd6dea39b835550a4d4fd4ca1ec98c50842eb557d5f55d3a8f8d566f7b8ea3a4473135101860b4d8decfc4d24f55ff5e389ac95d1d309d5504b632cf80c975e
diff --git a/dev-libs/ell/ell-0.57.ebuild b/dev-libs/ell/ell-0.57.ebuild
new file mode 100644
index 000000000000..5e79649bd337
--- /dev/null
+++ b/dev-libs/ell/ell-0.57.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic linux-info
+
+DESCRIPTION="Embedded Linux Library provides core, low-level functionality for system daemons"
+HOMEPAGE="https://01.org/ell"
+if [[ "${PV}" == *9999 ]] ; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://git.kernel.org/pub/scm/libs/ell/ell.git"
+else
+	SRC_URI="https://mirrors.edge.kernel.org/pub/linux/libs/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+LICENSE="LGPL-2.1"
+SLOT="0"
+
+IUSE="pie test"
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( sys-apps/dbus )"
+
+CONFIG_CHECK="
+	~TIMERFD
+	~EVENTFD
+	~CRYPTO_USER_API
+	~CRYPTO_USER_API_HASH
+	~CRYPTO_MD5
+	~CRYPTO_SHA1
+	~KEY_DH_OPERATIONS
+"
+
+src_prepare() {
+	default
+	sed -i -e "s#/tmp/ell-test-bus#/tmp/ell-test-bus-$(uuidgen)#" \
+		unit/test-dbus*.c unit/dbus.conf || die
+	[[ "${PV}" == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	append-cflags "-fsigned-char" #662694
+	local myeconfargs=(
+		$(use_enable pie)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name "*.la" -delete || die
+}
-- 
cgit v1.2.3-65-gdbad