From cd3aa48996a7801f8a366f471e3851e433aa662c Mon Sep 17 00:00:00 2001
From: Austin English <wizardedit@gentoo.org>
Date: Thu, 19 Jan 2017 17:52:54 -0600
Subject: games-engines/scummvm-tools: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: Portage-2.3.2, Repoman-2.3.1
---
 .../scummvm-tools/scummvm-tools-1.8.0-r1.ebuild    | 59 ++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 games-engines/scummvm-tools/scummvm-tools-1.8.0-r1.ebuild

(limited to 'games-engines/scummvm-tools/scummvm-tools-1.8.0-r1.ebuild')

diff --git a/games-engines/scummvm-tools/scummvm-tools-1.8.0-r1.ebuild b/games-engines/scummvm-tools/scummvm-tools-1.8.0-r1.ebuild
new file mode 100644
index 000000000000..94c6d12b097f
--- /dev/null
+++ b/games-engines/scummvm-tools/scummvm-tools-1.8.0-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+WX_GTK_VER=3.0
+inherit wxwidgets eutils flag-o-matic
+
+DESCRIPTION="utilities for the SCUMM game engine"
+HOMEPAGE="http://scummvm.sourceforge.net/"
+SRC_URI="http://scummvm.org/frs/scummvm-tools/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="flac iconv mad png vorbis"
+RESTRICT="test" # some tests require external files
+
+RDEPEND=">=dev-libs/boost-1.32
+	sys-libs/zlib
+	x11-libs/wxGTK:${WX_GTK_VER}
+	flac? ( media-libs/flac )
+	iconv? ( virtual/libiconv media-libs/freetype:2 )
+	mad? ( media-libs/libmad )
+	png? ( media-libs/libpng:0 )
+	vorbis? ( media-libs/libvorbis )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${P}-binprefix.patch"
+)
+
+src_prepare() {
+	default
+
+	need-wxwidgets unicode
+	rm -rf *.bat dists/win32 || die
+	sed -ri -e '/^(CC|CXX)\b/d' Makefile || die
+}
+
+src_configure() {
+	# Not an autoconf script
+	./configure \
+		--disable-tremor \
+		--enable-verbose-build \
+		--mandir=/usr/share/man \
+		$(use_enable flac) \
+		$(use_enable iconv) \
+		$(use_enable iconv freetype) \
+		$(use_enable mad) \
+		$(use_enable png) \
+		$(use_enable vorbis) || die
+}
+
+src_install() {
+	EXEPREFIX="${PN}-" default
+}
-- 
cgit v1.2.3-65-gdbad