From 7a7504d9f7b4cfe896820b7f690340816d09aa67 Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Sun, 27 Mar 2022 11:50:22 -0700
Subject: gnome-base/gnome-panel: Version bump to 3.44.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 gnome-base/gnome-panel/Manifest                  |  1 +
 gnome-base/gnome-panel/gnome-panel-3.44.0.ebuild | 73 ++++++++++++++++++++++++
 2 files changed, 74 insertions(+)
 create mode 100644 gnome-base/gnome-panel/gnome-panel-3.44.0.ebuild

(limited to 'gnome-base/gnome-panel')

diff --git a/gnome-base/gnome-panel/Manifest b/gnome-base/gnome-panel/Manifest
index edb5716e0fc8..f501457fa5aa 100644
--- a/gnome-base/gnome-panel/Manifest
+++ b/gnome-base/gnome-panel/Manifest
@@ -1 +1,2 @@
 DIST gnome-panel-3.42.0.tar.xz 2927280 BLAKE2B ec0490115d3d1e728f7b6dc85b915a8390148e55c0b9342ee1125c1bceb34cc4721d350e0bac01a5c55d5eede885938711a2b234eb3e28ba59b87feceee3b41c SHA512 834b5ed58f3444bddbf59caeb42740ee1fbd2bcea9914b69f9c14baa39cd8105d4e822f7e408a605ced3d6c4a69eb76a97c4e069b6466c88b2db7d7afed7540c
+DIST gnome-panel-3.44.0.tar.xz 2852688 BLAKE2B 2d31d9456cb94f5f7d4a7f02b1be7da901f79b32a098877d7b778570b67c7f9be42105f5dbcf0ee6eacdf5359349c31140677b87eedbe9c1516f63104be668d1 SHA512 b3300f6943c970b9a2ea27b9459ab82e634226372006b7748551e6c8c24897c9df4ab2bc5528eae6758d9cd431cb2428465ef30fdcc012ddac7c69cd4f43f966
diff --git a/gnome-base/gnome-panel/gnome-panel-3.44.0.ebuild b/gnome-base/gnome-panel/gnome-panel-3.44.0.ebuild
new file mode 100644
index 000000000000..ab207cb1486c
--- /dev/null
+++ b/gnome-base/gnome-panel/gnome-panel-3.44.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome2 toolchain-funcs
+
+DESCRIPTION="The GNOME Flashback Panel"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-panel/"
+
+LICENSE="GPL-2+ FDL-1.1 LGPL-2.1+"
+SLOT="0"
+IUSE="eds elogind systemd"
+REQUIRED_USE="^^ ( elogind systemd )"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="
+	>=gnome-base/gnome-desktop-2.91.0:3=
+	>=x11-libs/gdk-pixbuf-2.26.0:2
+	>=x11-libs/pango-1.15.4
+	>=dev-libs/glib-2.67.1:2
+	>=x11-libs/gtk+-3.22.0:3[X]
+	>=x11-libs/libwnck-40.0:3
+	>=gnome-base/gnome-menus-3.7.90:3
+	eds? ( >=gnome-extra/evolution-data-server-3.33.2:= )
+	elogind? ( >=sys-auth/elogind-230 )
+	systemd? ( >=sys-apps/systemd-230:= )
+	>=x11-libs/cairo-1.0.0[X,glib]
+	>=dev-libs/libgweather-3.91.0:4=
+	>=gnome-base/dconf-0.13.4
+	>=x11-libs/libXrandr-1.3.0
+	gnome-base/gdm
+	x11-libs/libX11
+	x11-libs/libXi
+	sys-auth/polkit
+	x11-libs/libXi
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+" # yelp-tools and autoconf-archive for eautoreconf
+
+src_configure() {
+	local myconf=(
+		--disable-static
+		$(use_enable eds)
+	)
+
+	# Below elogind MENU_* pkg-config calls need to match up with what upstream has
+	# each version (libsystemd replaced with libelogind). Explicit per-version die
+	# to force a manual recheck. Only update the explicit version if the
+	# "PKG_CHECK_MODULES([MENU], ...)" block did not change; otherwise adjust
+	# elogind conditional block below accordingly first.
+	if ver_test ${PV} -ne 3.44.0; then
+		die "Maintainer has not checked over packages MENU pkg-config deps for elogind support"
+	fi
+
+	if use elogind; then
+		local pkgconfig="$(tc-getPKG_CONFIG)"
+		myconf+=(
+			MENU_CFLAGS="$(${pkgconfig} --cflags gdm gio-unix-2.0 gtk+-3.0 libgnome-menu-3.0 libelogind)"
+			MENU_LIBS="$(${pkgconfig} --libs gdm gio-unix-2.0 gtk+-3.0 libgnome-menu-3.0 libelogind)"
+		)
+	fi
+
+	gnome2_src_configure "${myconf[@]}"
+}
-- 
cgit v1.2.3-65-gdbad