From bf8512d598d6e4979f9c12a7c6e5e82e476c5b4d Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 10 Jan 2019 09:47:19 +0100
Subject: kde-apps: Drop KDE Applications 18.12.0

Package-Manager: Portage-2.3.54, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/akonadi/Manifest               |   1 -
 kde-apps/akonadi/akonadi-18.12.0.ebuild | 110 --------------------------------
 2 files changed, 111 deletions(-)
 delete mode 100644 kde-apps/akonadi/akonadi-18.12.0.ebuild

(limited to 'kde-apps/akonadi')

diff --git a/kde-apps/akonadi/Manifest b/kde-apps/akonadi/Manifest
index 57536141346c..c9eb4e9726ea 100644
--- a/kde-apps/akonadi/Manifest
+++ b/kde-apps/akonadi/Manifest
@@ -1,3 +1,2 @@
 DIST akonadi-18.08.3.tar.xz 1538188 BLAKE2B 333c86802418f86f2336408d1e63ce16a9fc50267f7d5cb39f177eb6aab1ddc8479fa9384f323f8aad0ac4157d8abfe8de237bcc6bd058b19fe596442c7f20e1 SHA512 ba883902ad83c989bb480712c0b3871e683307ecb121f1d7b3e433b9211056cda209d9640a7bae520fb4b6611950863180b879269797a606af2ac25ae4f24cc0
-DIST akonadi-18.12.0.tar.xz 1552448 BLAKE2B 6c43baecee56ca5131f6bf58e9b6103051316f946a0d7609c5c1a99949ff86caa5b175be1e17de3a466119da92c133c5eae11449ae91c186d3297601714f2938 SHA512 1a37fe66acfe9001ec84849f0abd3a54b38c21421cbec537f86b0af0b30c2120eca8236afeb0d64e795bdfc4f116c6cafb1c2edd92d8ec6208ea5cc2ca642e07
 DIST akonadi-18.12.1.tar.xz 1552724 BLAKE2B 7e47c48ecbc25b450df9cffabb6b019003f03a66c5fc214db0d183085b9dd9fbbd8443fb6906837e85d3e554a0d603f8e657db8ddf6bb5795a055f9f51b84aac SHA512 9d20f4b283c00f20a0b3c1a40041bb5b1adff6197fef5d6bc12ff7ea013de2809bafa3ffac0f70494b659e5972bc00f73e7df9d7d3d3157deabbebad5811c5ec
diff --git a/kde-apps/akonadi/akonadi-18.12.0.ebuild b/kde-apps/akonadi/akonadi-18.12.0.ebuild
deleted file mode 100644
index 27df4a99621a..000000000000
--- a/kde-apps/akonadi/akonadi-18.12.0.ebuild
+++ /dev/null
@@ -1,110 +0,0 @@
-# Copyright 1999-2018 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-KDE_DESIGNERPLUGIN="true"
-KDE_TEST="forceoptional"
-VIRTUALDBUS_TEST="true"
-VIRTUALX_REQUIRED="test"
-inherit kde5
-
-DESCRIPTION="Storage service for PIM data and libraries for PIM apps"
-HOMEPAGE="https://community.kde.org/KDE_PIM/akonadi"
-
-KEYWORDS="~amd64 ~arm ~x86"
-LICENSE="LGPL-2.1+"
-IUSE="+mysql postgres sqlite tools xml"
-
-REQUIRED_USE="|| ( mysql postgres sqlite ) test? ( tools )"
-
-COMMON_DEPEND="
-	$(add_frameworks_dep kcompletion)
-	$(add_frameworks_dep kconfig)
-	$(add_frameworks_dep kconfigwidgets)
-	$(add_frameworks_dep kcoreaddons)
-	$(add_frameworks_dep kcrash)
-	$(add_frameworks_dep kdbusaddons)
-	$(add_frameworks_dep ki18n)
-	$(add_frameworks_dep kiconthemes)
-	$(add_frameworks_dep kio)
-	$(add_frameworks_dep kitemmodels)
-	$(add_frameworks_dep kitemviews)
-	$(add_frameworks_dep kwidgetsaddons)
-	$(add_frameworks_dep kwindowsystem)
-	$(add_frameworks_dep kxmlgui)
-	$(add_qt_dep qtdbus)
-	$(add_qt_dep qtgui)
-	$(add_qt_dep qtnetwork)
-	$(add_qt_dep qtsql 'mysql?,postgres?')
-	$(add_qt_dep qtwidgets)
-	$(add_qt_dep qtxml)
-	x11-misc/shared-mime-info
-	sqlite? ( dev-db/sqlite:3 )
-	xml? ( dev-libs/libxml2 )
-"
-DEPEND="${COMMON_DEPEND}
-	dev-libs/boost
-	dev-libs/libxslt
-	test? ( sys-apps/dbus )
-"
-RDEPEND="${COMMON_DEPEND}
-	!<kde-apps/kapptemplate-17.11.80
-	!kde-apps/kdepim-l10n
-	!kde-apps/kdepimlibs
-	mysql? ( virtual/mysql )
-	postgres? ( dev-db/postgresql )
-"
-
-# some akonadi tests time out, that probably needs more work as it's ~700 tests
-RESTRICT+=" test"
-
-PATCHES=( "${FILESDIR}/${PN}-17.03.80-mysql56-crash.patch" )
-
-pkg_setup() {
-	# Set default storage backend in order: MySQL, PostgreSQL, SQLite
-	# reverse driver check to keep the order
-	use sqlite && DRIVER="QSQLITE3"
-	use postgres && DRIVER="QPSQL"
-	use mysql && DRIVER="QMYSQL"
-
-	if use sqlite || has_version "<${CATEGORY}/${P}[sqlite]"; then
-		ewarn "We strongly recommend you change your Akonadi database backend to either MySQL"
-		ewarn "or PostgreSQL in your user configuration."
-		ewarn "In particular, kde-apps/kmail does not work properly with the sqlite backend."
-	fi
-
-	kde5_pkg_setup
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DAKONADI_BUILD_QSQLITE=$(usex sqlite)
-		-DBUILD_TOOLS=$(usex tools)
-		$(cmake-utils_use_find_package xml LibXml2)
-	)
-
-	kde5_src_configure
-}
-
-src_install() {
-	# Who knows, maybe it accidentally fixes our permission issues
-	cat <<-EOF > "${T}"/akonadiserverrc
-[%General]
-Driver=${DRIVER}
-EOF
-	insinto /usr/share/config/akonadi
-	doins "${T}"/akonadiserverrc
-
-	kde5_src_install
-}
-
-pkg_postinst() {
-	kde5_pkg_postinst
-	elog "You can select the storage backend in ~/.config/akonadi/akonadiserverrc."
-	elog "Available drivers are:"
-	use mysql && elog "  QMYSQL"
-	use postgres && elog "  QPSQL"
-	use sqlite && elog "  QSQLITE3"
-	elog "${DRIVER} has been set as your default akonadi storage backend."
-}
-- 
cgit v1.2.3-65-gdbad