From 4fdbb8616f65cf59f68712d78b5b3c555481c4c1 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 12 Jul 2022 17:32:21 +0200
Subject: kde-plasma/plasma-firewall: 5.24.6 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-plasma/plasma-firewall/Manifest                |  1 +
 .../plasma-firewall/plasma-firewall-5.24.6.ebuild  | 64 ++++++++++++++++++++++
 2 files changed, 65 insertions(+)
 create mode 100644 kde-plasma/plasma-firewall/plasma-firewall-5.24.6.ebuild

(limited to 'kde-plasma/plasma-firewall')

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index bf8f8421582c..863187393957 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.24.5.tar.xz 346660 BLAKE2B 767cd4722325e8035735b744afdccfe4114e68756919f3904fcbd2aa25879b09b7bb4fcaffcaf0a2687f5744e1177fb177658b6af0ed3fef7838498c99f583a3 SHA512 4c774b10c32929399a8b01007e3c34ab702803a0aa80ea812bbcc4d4ead02d0e64136f575454fdc2f0e938740afbf6d48025c654831aa5485b86253418bf13d1
+DIST plasma-firewall-5.24.6.tar.xz 346668 BLAKE2B 857b90f383798961d32d9a65f65cec4f7b45dc17c56966bbe71ee4068c8bbadee941d0ce2a439dc99ec3a9327d5d1d4189d327a820ab618818090ff7661d4865 SHA512 b75442205d1b2eed986794ff6ea233e31e904de36e8acabc7ef2da83b94fdebcaf6a0fa26d5b0393921e9b0acc6d62bbd71f711e13f3e6ba455710970e5af26f
 DIST plasma-firewall-5.25.2.tar.xz 355264 BLAKE2B c574fe5e528146758dd26e029852cd6ea0230e93e997f5eae7555d56997b02aae7bb3c540059d9631f65066921d4357baf8d5c07e3055aeaeed70a4ea5e4cacd SHA512 d462cc1aceed6b6c2aa2d88e7a213fec120e7dad6ea37b61031e38300600a688a1bd4ff0b0a979fe270b69723c891576ce490012975e5fffb55d65a0ca519750
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.24.6.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.24.6.ebuild
new file mode 100644
index 000000000000..238d163f8917
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.24.6.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+KFMIN=5.92.0
+QTMIN=5.15.4
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad