Version bump for Gnome 3.12.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 82 insertions, 1 deletions

diff --git a/gnome-extra/gnome-tweak-tool/ChangeLog b/gnome-extra/gnome-tweak-tool/ChangeLog
index f1134f1232de..18bf88f19678 100644
--- a/gnome-extra/gnome-tweak-tool/ChangeLog
+++ b/gnome-extra/gnome-tweak-tool/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/gnome-tweak-tool
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog,v 1.33 2014/04/26 08:24:04 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-tweak-tool/ChangeLog,v 1.34 2014/04/27 17:17:46 eva Exp $
+
+*gnome-tweak-tool-3.12.0 (27 Apr 2014)
+
+  27 Apr 2014; Gilles Dartiguelongue <eva@gentoo.org>
+  +gnome-tweak-tool-3.12.0.ebuild:
+  Version bump for Gnome 3.12.
 
   26 Apr 2014; Pacho Ramos <pacho@gentoo.org> -gnome-tweak-tool-3.8.1-r1.ebuild:
   drop old
diff --git a/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.12.0.ebuild b/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.12.0.ebuild
new file mode 100644
index 000000000000..8fa70f9bd549
--- /dev/null
+++ b/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.12.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-tweak-tool/gnome-tweak-tool-3.12.0.ebuild,v 1.1 2014/04/27 17:17:46 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils gnome2 python-r1
+
+DESCRIPTION="Tool to customize GNOME 3 options"
+HOMEPAGE="https://wiki.gnome.org/action/show/Apps/GnomeTweakTool"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+# Newer pygobject needed due upstream bug #723951
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=gnome-base/gsettings-desktop-schemas-3.4
+	>=dev-python/pygobject-3.10.2:3[${PYTHON_USEDEP}]
+"
+# g-s-d, gnome-desktop, gnome-shell etc. needed at runtime for the gsettings schemas
+RDEPEND="${COMMON_DEPEND}
+	>=gnome-base/gnome-desktop-3.6.0.1:3=[introspection]
+	>=x11-libs/gtk+-3.12:3[introspection]
+
+	net-libs/libsoup[introspection]
+	x11-libs/libnotify[introspection]
+
+	>=gnome-base/gnome-settings-daemon-3
+	gnome-base/gnome-shell
+	>=gnome-base/nautilus-3
+	x11-wm/metacity
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40.0
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	# Add contents of Gentoo's cursor theme directory to cursor theme list
+	epatch "${FILESDIR}/${PN}-3.10.1-gentoo-cursor-themes.patch"
+
+	# Prevent problems setting WM preferences, upstream bug #706834
+	epatch "${FILESDIR}/${PN}-3.8.1-wm-preferences.patch"
+
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	install_python() {
+		gnome2_src_install
+		python_doscript gnome-tweak-tool || die
+	}
+	python_foreach_impl run_in_build_dir install_python
+}